*temp checkedout false
*temp introuble false
*if ((inform1 > 4) and (not (footagedestroy)))
    *set introuble true
*temp infocounter 0

*if (shades)
    *set infocounter +1
*if (logs)
     *set infocounter +1
*if (photo)
     *set infocounter +1
*if (weirdblood)
     *set infocounter +1
*if (hatch)
     *set infocounter +1

*temp cgtalk 3
*temp untether false
*temp tellairy false
*temp ontome false
*temp imfinnicky false
*temp cgmoment false
*temp aboutwork 0
*temp yeahhh false
*temp disloyal false

*label startover
*if coven_history = 1
    [i]Drag yourself off the filthy mattress. Spit defiance at the shaven-headed asshole, the first person you see every morning.[/i]

    [i]Take a beating.[/i]

    [i]If you aren't too battered, rail at him some more.[/i]

    [i]Take another beating.[/i]

    [i]Depending on the day, be too hurt or just about hold your temper, and get carted through more bullshit with additional assholes.[/i]

    [i]Alternatively, keep resisting. Get tossed back in the cage. Spend the rest of the day wondering if they just let the monster eat you this time.[/i]

    [i]Rinse. Repeat. Redo. one two three.[/i]

    [i]'till the day you can't face the thought of more time in the cage, more trebled punches from those fists.[/i]

    [i]And then it happens anyway. Again. Again. Again.[/i]
    
    *page_break
    
    [i]At night—not that you know night from day, locked away—you lie awake. On the mattress if you're lucky, the floor if you're not, that monster snapping its jaws at you.[/i]
    
    [i]Feel the bruises, the barely-treated cuts. The stabbing pain in your chest, probably a cracked rib.[/i]
    
    [i]Think that…[/i]
    *choice
        #[i]I just want to die.[/i]
            *set terminate +1
            [i]Why couldn't it have killed you, down there in that place?[/i]
            
            [i]This isn't survival, this isn't living.[/i]
            
            [i]you're meat to them. something to be used.[/i]
            
            [i]all you want is for it to be over.[/i]
            
            [i]let this nightmare end.[/i]
            
        #[i]please. please. please stop hurting me.[/i]
            [i]You're past resistance. You're past fighting back.[/i]
            
            [i]you just want this to stop. it doesn't matter anymore, you'll do whatever they want.[/i]
            
            [i]just… just stop.[/i]
            
            [i]please.[/i]
            
            [i]please.[/i]
            
        #[i]I'm not strong enough.[/i]
            [i]Not to endure this. Not to keep fighting.[/i]
            
            [i]You can't face the thought of another 'lesson' at those hands.[/i]
            
            [i]submission is all that's left.[/i]
            
    *page_break One. Two. Three.    
    *goto backnow

*elseif coven_history = 2
    [i]Each morning you clamber off the filthy mattress, scurry to the door of your cell, and wait to be told what to do.[/i]
    
    [i]When the shaven-headed man shows up, he might beat you. Might not.[/i]

    [i]You tell yourself he's been hitting you less the more compliant you are. You try to push down the angry—later tired—voice in your head that reminds you he'll often hit you anyway.[/i]

    [i]Listen attentively to the scholarly gentleman with the glasses, hold back your shivers at hearing the same voice which narrated your purgatory tied to an examination table.[/i]

    [i]Demonstrate your powers however you're bid. Flinch whenever you're forced to admit that a task is beyond your capabilities, no matter the lengths you push yourself.[/i]

    [i]"That is quite all right, Paradigm. The more data we have on your expression of the formula, the better."[/i]

    [i]Feel the pathetic urge to thank him for not punishing you, because the other one—Catalyst—would hit you until satisfied he can't beat the objective out of you.  [/i]

    [i]Do as you're told. Keep your head down. Make the best of a bad situation.[/i]

    [i]You just have to prove yourself.[/i]
    
    *page_break
    [i]You don't know night from day in here. How long has it been since you saw anything beyond grey walls?[/i]
    
    [i]Well, night's what you call it, because it's when you're supposed to sleep, when you're not laying awake, staring at the ceiling, wincing as each breath agitates a fresh-bruised rib.[/i]
    
    [i]Think…[/i]
    
    *choice
        #[i]If I died, would it even matter?[/i]
            *set terminate +1
            [i]What does it say, that the only purpose you can find is obeying the jailers?[/i]
            
            [i]Survival isn't living.[/i]
            
            [i]Is there any point to this, if all you can achieve is existence? Is that what you've been reduced to?[/i]
            
            [i]Why bother.[/i]
            
        #[i]Just follow orders, and I'll be okay.[/i]
            [i]Stay useful, stay valued, stay alive.[/i]
            
            [i]Day by day, that's what matters.[/i]
            
            [i]You're still alive.[/i]
            
        #[i]Tomorrow will be better.[/i]
            [i]It won't be easy, or fast, but you can improve your situation.[/i]
            
            [i]There will be a light, if you look for it. Have to start somewhere.[/i]
            
            [i]Keep your feet planted, don't get carried away.[/i]
            
            [i]They'll trust you eventually. They have to. They have to.[/i]
            
            
    *page_break
    *goto backnow

*else
    [i]Drag yourself off the filthy mattress, battle the urge to spit defiance at the shaven-headed asshole, the first person you see every morning.[/i]
    
    [i]Wait and see if you'll get to greet the new day with a beating. There's no pattern, you've figured out. He'll hit you if he feels like, or he's in a bad mood, or he just doesn't like the way that you're standing today.[/i]

    [i]You fought the first few times. Struggled the next few. Now you let it happen.[/i]

    [i]Rescue isn't coming. Escape won't be a matter of heroism and daring. You can't win a head-on confrontation, and any attempt will see them tighten your shackles, or throw you back into the cage while you wait to see if they'll just let the monster eat you this time.[/i]

    [i]Be smart. Play your role. [b]Inhabit[/b] your role. Let them see what they want to see.[/i]

    [i]Hold in the hate while the scholarly man drones at you. Hide that his voice—the voice of your examination table purgatory—is like a drill to your skull.[/i]

    [i]Perform as they ask, demonstrate your powers. Be a good subject.[/i]

    [i]Do as you're told. Keep your head down. Build up their trust.[/i]

    [i]The moment will come. It must.[/i]
    
    *page_break
    
    [i]At night—or what passes for it, locked in a place outside of time—you lie awake, daring to scheme.[/i]
    
    [i]There must be a purpose to all this. Experiments serve a goal. These powers and that monster serve an end. If they were going to kill you, they would have done it already.[/i]
    
    [i]If they believe you're an asset, then they may just open the cage for you.[/i]
    
    [i]For now…[/i]
    *choice
        #[i]Plotting is my only distraction from the constant urges to just... end it.[/i]
            *set terminate +1
            [i]All your plans and all your clever deceptions fail to address that there's a very simple escape route.[/i]
            
            [i]Even if you somehow free yourself, what then? Prii and @{alive Shauna|Grant} will still be dead. You'll still have this… thing infesting your body.[/i]
            
            [i]Weeks or months or years of scheming. Is the effort even worth the reward?[/i]
            
            [i]You could be done with this. With everything.[/i]
            
            [i]But playing pretend keeps you going. At least a little while longer.[/i]
            
        #[i]Bide my time.[/i]
            [i]That's the only option. Endure the indignities and the pain, and [b]wait.[/b]
            
            [i]This won't happen overnight, or in a week, or a month.[/i]
            
            [i]Patience is a virtue.[/i]
            
        #[i]Fantasise on vengeance.[/i]
            [i]Cramming Catalyst's fist back down his throat. Smashing Hypothesis's glasses into his eyes. Lighting the monster ablaze and watching it burn.[/i]
            
            [i]Bright, hateful thoughts keep you warm through the lonely nights.[/i] 
            
            [i]One day, you will have your chance.[/i]
            
    *page_break
     
*label backnow
"Perfect timing, little ${mc_sibling}. Could use your help with this." Catalyst speaks casually, like his knuckles aren't slicked with blood, stains spotting his clothing, like he isn't dragging a dead man along on a plastic sheet.

"What the fuck is that, man?" growls $!{cg}, though you'd describe her tone as more put out than perturbed.

"Dead guy." Catalyst's focus remains on you specifically. $!{cg} makes an irritated noise, and he grins wider. "Some drifter I caught camping out by the building. Nobody's gonna miss him."

"It's the middle of the day."

"We've got blind spots. Shut the fuck up. [i]Dime[/i]. Help me with this." Catalyst gestures at the corpse again. "It's feeding time." He leers.

*if rel_cg > 60
    Before you can reply, $!{cg} intercedes again. "Cut ${mc_him} some slack, Catalyst. $!{mc_he}'@{mc_singular s|ve} had a day of it. I'll help."
    
    This time, she actually manages to draw Catalyst's attention. He scowls. "No, you're gonna get your ass over to Hypothesis, and Dime's gonna do as ${mc_he}'@{mc_singular s|re} told."
    
    "Dude, come on—"
    
    "Fuck off, or I'mma feed you your own teeth."
    
    $!{cg}'s jaw tightens. Then, her shoulders slowly slump. "Sorry," she mutters to you, then walks away up the corridor, head down.
    
*else
    $!{cg} looks at you, hesitating. Then, her eyes drop and she dips her head into a nod. "Catch you two in a bit, then."
    
    
As she passes him, Catalyst calls over his shoulder. "Hypothesis wants you first. Better haul ass!" Then he's back to you, still grinning. "C'mon. I've [i]missed you.[/i]"
*choice
    #Try not to look at the body.
        *if brutal > 0
            *set brutal - 1
            
        You stoop to grip a corner of the sheet, holding your head rigid to keep the pulverised corpse at the very periphery of your vision.
        
    #Let's just get it over with.
        You walk over, grabbing a corner of the sheet. The dead man's face is an unrecognisable mass of bloody meat. You try to block the sight from your mind.
        
    #Feign enthusiasm.
        "Sure thing," you say, heading over to grab a corner of the sheet. @{coven_history Fear adds an urgency to your step.|Quickly and without protest, that's the way.|He's in something approaching a decent mood. Best to try and maintain it.}
        
Together, you drag the body along the corridor, rounding a corner to stop before a heavily-reinforced door, almost a bulkhead. Catalyst grabs the wheel affixed to it, grunting with exertion as he rotates the wheel. Mechanisms clunk and clatter, and then Catalyst heaves the door open, the metallic screech of the hinges echoing off the walls.
 
They're answered by a low, rumbling growl from within.
 
You swallow, breath quickening. Your body locks.
 
A blow—[i]two three[/i]—thuds between your shoulders, almost sending you to the ground before your uncooperative legs manage to stumble, catching you,
 
"Scared?" Catalyst jeers. "Move your ass, Dime."
 
Shambling, you force yourself to cross over before Catalyst does it for you. Fear alone does not cover the numbing cold sweeping through your system. Fear alone does not describe the spectral hand squeezing your throat, your chest, your skull.
 
A fetid stench assaults your senses, blood and filth and decay.
 
Light doesn't stretch to the corners of the space within, cloaking it in shadow. Ahead of you, the centre of the room plunges into a square pit covered by a grid of metal bars.
 
Though everything you have screams to stay away, you inch forward. Catalyst will only hit you again if you stand still. You continue to shuffle to the pit's edge.

Dozens of eyes gleam in the dark. One after another, they fix upon you.
 
The Project snarls.
 
*page_break 
 
[i]Propped up against the wall, @{prologuehealth your aching body is almost an afterthought.|your torn body aches with every movement, the gouges of the monster's claws barely held together by the cursory treatment afforded by your captors.|you intermittently taste blood in your mouth, trickling through from your broken nose. It's almost grown familiar.|it's difficult to muster the strength to move, your shoulder screaming protest with every motion, a visceral reminder of the monster's fangs sinking into your flesh. The wound is barely treated, sure to fester.}[/i]
 
[i]The empty pits of @{alive Shauna's|Grant's} eyes follow wherever you go. Last time the monster took a chunk off @{alive her|him}, @{alive her|his} face ended up turned towards your cell.[/i]

[i]'Cell' is almost too generous. You can touch the wall and the bars—all that holds the creature at bay—at the same time while barely extending your arms.[/i]

[i]There's nowhere to hide. Not from the creature, not from the sickly scent of a decomposing corpse, and not from @{alive Shauna's|Grant's} awful stare.[/i]
 
[i]With Prii, you could occasionally trick yourself that it wasn't them in there, altered as they were by their powers. They were just different enough to temporarily cling to the delusion, a shred of comfort while listening to the monster crunching their bones and tearing their flesh. @{(brokenheart = 2) It's the only thing that kept you even a little sane as your love was eaten three feet away.|}[/i]

[i]You can't begin to do that with @{alive Shauna|Grant}. Not like it was working to start.[/i]

*if alive = 1
    [i]Shauna is—Shauna was—the sweetest person you've ever known. For this to happen to her seems like a fucked up cosmic joke.[/i]
    
    [i]There was never a chance. What were any of you supposed to do against something out of a nightmare?[/i]
    
    *if brokenheart = 3
        *gosub lovevariations
        
        
    *else
        [i]Nobody deserves to die like that, but Shauna least of all. @{(lasthelp = 1) What does it matter you were there for her? She bled out scared and in pain.|}[/i]
    
    
    [i]@{(brokenheart = 3) The brightest star in your sky|Your friend} discarded like so much meat. Carrion.[/i]
    
    [i]She wanted to leave. @{turnback Why wouldn't the others just listen to you?|And none of you listened.}[/i]
    
*else
    [i]Grant is—Grant was—the mood maker of your friends, always ready to laugh or crack a joke. Someone like him shouldn't just… die and be left to rot.[/i]
    
    [i]He saved your life. He saw a monster, and his first thought was to throw himself on top of you. There wasn't even a chance to thank him before he was gone.[/i]
    
    *if brokenheart = 4
        *gosub lovevariations
        
        
    *else
        [i]Of anyone, for Grant to just… bleed out in some forgotten basement seems unreal. Unfair. People would so often dismiss him as unreliable, but he was there when it counted.[/i]
        
        
    [i]@{(brokenheart = 4) The brightest star in your sky|Your friend} discarded like so much meat. Carrion.[/i]
    
    [i]Would it have mattered, if you went with Beth?[/i]
    
    [i]At least you could have said goodbye.[/i]
 
*page_break
[i]By the time @{alive she's|he's} truly unrecognisable, the accusing stare of @{alive her|his} dead face is seared into your memories.[/i]

[i]You wonder if you're next on the menu. The creature ate @{alive Shauna|Grant} faster than Prii. Perhaps it just grows hungrier with time. Perhaps it prefers fresh meat.[/i]

[i]So you huddle in your corner, knees hugged to your chest, while death paces back and forth at arm's length, hungering, ever hungering, always watching. It sniffs and tastes the air, and saliva drips from its many jaws.[/i]

*choice
    #[i]I dream of rescue.[/i]
        [i]You haven't seen Beth or @{alive Grant|Shauna}. If they were dead, then surely they'd have been fed to the monster too. If they're alive, there's no evidence of their capture.[/i]
        
        *if ((origin = 2) or (origin = 6))
            [i]They must have escaped. You were right there at the doors to see them get away. And if they're out there, then they wouldn't just abandon you. They wouldn't.[/i]
            
        *else
            [i]And if they didn't escape, why would these people, whoever they are, leave their base in such a hurry? You were in the back of a truck for a spell. They moved you.[/i]
            
            [i]That thought is tinged with gut-churning doubt. If your captors relocated, then the cavalry will have a hard time coming to the rescue.[/i]
        
        [i]Day by day you cling to the hope of salvation, even as it grows fainter and ever more sickly.[/i]
        
    #[i]I imagine conversations with my friends.[/i]
        [i]It's easy enough to bring them to mind. Harder to divert 'Prii' and @{alive 'Shauna'|'Grant'} from accusing you of letting them die.[/i]
        
        [i]That empty gaze isn't vacating your mindscape anytime soon.[/i]
        
        [i]Still, you invent jokes from Grant and encouragement from Shauna. You imagine Prii telling you what they'll do after this, and Beth pointing out details of your environment.[/i]
        
        [i]Sometimes you talk back, up until the monster silences you with another vicious snarl.[/i]
        
        [i]Is this keeping you sane, or driving you to the cliff edge?[/i]
        
    #[i]I untether myself. This is happening to somebody else.[/i]
        *set untether true
        [i]If you don't let it reach you, then you're not here.[/i]
        
        [i]You're an observer. The $!{forename} there in the cell is someone on the other side of a window.[/i]
        
        [i]It's not you. This isn't real.[/i]
        
        [i]It's not you. This isn't real.[/i]
        
    #[i]I talk to the monster.[/i]
        [i]It has little to say. Your only reward is garnering its attention, swiftly followed by more attempts to reach at you through the bars.[/i]
        
        [i]You talk anyway. There's a morbid kind of amusement in asking how its day has been, what it thinks of the lodgings, if your captors are treating it well.[/i]
        
        [i]Every so often, you halfway convince yourself that it's listening to you, that there's a glint in one eye or another that speaks more to curiosity than hunger.[/i]
        
        [i]…but that's probably the pain, fatigue, loneliness, and existential dread playing tricks on you.[/i]
        
    #[i]I scream myself hoarse, calling for help.[/i]
        [i]You call out with everything you've got, shouting until your throat feels like you've swallowed glass. The monster next door snaps and snarls at your noise, but you push beyond the fear and the pain to redouble your efforts, screaming your desperation into the void.[/i]
        
        [i]For a day or two. Then the shaven-headed man gets sick of your 'squealing' and batters you until you stop.[/i]
        
        *label trebled
        [i]The rhythm of his fists is already growing familiar, every blow trebled.[/i]
      
    #[i]I rage at the monster.[/i]
        [i]You scream your hate at the beast, channelling your grief into anger at what it's taken.[/i]
        
        [i]It responds, snarling and spitting, gnawing at the bars of your cell. At times it [b]howls[/b], silencing you in an instant.[/i]
        
        [i]Intermittently, the man with the shaven head interrupts your shouting matches and batters you until you 'shut the fuck up'.[/i]
        
        *goto trebled

[i]And alongside you, the monster paces ceaselessly.[/i]
*page_break

With gritted teeth and clenched jaw, you physically jerk your head to the side, wrenching yourself free of the Project's paralysing gaze. The motion is so forceful as to set you stumbling again, swaying to regain your balance.

Whenever that horde of mismatched eyes fixes upon you, you're instantly transported, whether back to the cell or the very moment you opened the gates of hell.

If anything, absence has only made it worse.

There's movement at your elbow, and you hastily straighten up, not needing to look to know that Catalyst is en route to refocus you by way of a fist.

A huff of breath that's probably disappointment. "If you're done pissing yourself, little ${mc_sibling}, our friend here is hungry."

Catalyst grabs a long handle affixed to a small square hatch set amongst the bars, and tugs it open. Immediately, the Project rears up on its hind legs, snapping at the opening with one set of jaws. Two taloned paws scrabble at the bars, trying to force them further apart.

It's far too small a gap for the beast to clamber through, but as the grating screech of claws on metal fills the air, you can't stop yourself staring, frozen like a deer in the headlights.

[i]The monster is crammed halfway through the doors. It thrashes, hissing and snarling, ichor dripping from its mouths. Bit by bit, it forces itself through the opening.[/i]

A clubbing shot to the side of your head almost puts you on the floor. The echoes finish the job. Didn't see it coming this time.

"Fucking pay attention," Catalyst snaps. "I swear, you got even dumber since you went outside." Grabbing a fistful of your shirt, he drags you to your feet, then shoves you towards the corpse.

An involuntary shudder runs through your body. Whenever he touches you, you're flinching for what comes next.

One two three.
*goto feeding

*label lovevariations
[i]In @{alive Shauna's|Grant's} place there's a gaping hole that only grows larger the longer @{alive her—her|his—his} body rots on the floor, grief's greedy claws ripping at your seams.[/i]
        
*if ((dated_shauna) or (dated_grant))
    [i]All the love and affection you shared, snatched away in a single night.[/i]

*else
    *if (confession)
        [i]And right at the end, she admitted her feelings. You both felt the same way. And now she's gone.[/i]

    *else
        [i]Those empty eyes seem to mock you, remind you that you kept hesitating and hesitating, and now your chance is gone forever.[/i]
        
*return

*label feeding
*choice
    #Apologise.
        "Sorry," you mutter, head lowered @{coven_history and body folding into familiar submission.|in deference.|in your best imitation of deference.}
        
        Catalyst snorts in derision. "Quit wasting time."
        
        You hop to it, hurrying to the dead man.
        
    #Just get it done.
        Catalyst is going to keep being Catalyst. The sooner you finish this errand, the sooner you get clear of him.
        
        Without a word, you move over to the dead man.
        
    *selectable_if (defiance > 3) #Insult him under my breath.
        "Asshole," you mutter. 
        
        *if coven_history = 1
          Fleeting catharsis drowns beneath a wave of icy terror. Resistance only brings pain. That isn't a lesson you should be forgetting. Not ever.
        
          Already you're trembling, anticipating punishment.
        
          None follows.
          
          He didn't hear.
          
          You scramble over to the dead man before Catalyst can decide to hurry you along.
          
        *else
            @{coven_history |Then, you blink, taken aback by your own response.|Satisfying to say it aloud. If a little foolish. A petty swipe at Catalyst isn't worth giving the game away.}
            
            @{coven_history |That's not according to script. Neither is the defiant spark in your chest.|He isn't reacting though, so you're confident that you weren't heard. Catalyst doesn't have the self-control not to fly off the handle at an insult.}
            
            @{coven_history |Steadying yourself, you move over to the dead man.|You stash the little mote of satisfaction away in your mind, and move over to the dead man.}
    
It's cumbersome work to haul the corpse upright, and Catalyst doesn't lift a finger to help as you're forced to hook your hands under its armpits. The corpse's head lolls against your chest, its broken mess of a face gazing up at you. @{guiltkill The man you killed swims to the surface of your mind, and you gag, fighting off the urge to throw the body to the floor.|You try not to retch.}

@{(guts < 15) Your arms are beginning to tremble with the weight, and as you adjust your grip, you almost fumble it entirely. Overcorrecting, you wind up with an arm wrapped around the body's shoulder and your face pressed far too closely to that of your cargo.|The literal dead weight has you grimacing with exertion as you drag your cargo over to the edge of the pit.} Had that night gone just a little differently, this would have been you.

Which of you is the luckier?

At the last moment, Catalyst finally deigns to step in, roughly commandeering one of the corpse's arms. "Not like your scrawny ass could toss him that far," he says, just in case you were in danger of believing he's being nice. 

Together, you heave the body out over the pit and through the open hatch. The Project snaps at it in midair, seizing the corpse by the arm and dragging it the rest of the way down into its lair. A rumbling noise half a bark and half a purr emanates from a couple of its mouths as it begins pawing and sniffing the special delivery.

You step back before it can begin to eat in earnest. Too late, you realise your mistake as your back bumps something solid—Catalyst must have slipped behind you—and then his arms are coiling around your shoulders, his hand gripping @{(mc_hairlength = 3) the back of your skull in a vice.|a fistful of your hair.} @{coven_history You go rigid, seized by revulsion and terror, mind flashing with the echoes of countless beatings.|You go limp, not putting up any resistance. It's ingrained, at this point.|You almost start to struggle before remembering yourself, intentionally going limp in his grasp,}

"What's the hurry, Dime?" Catalyst's voice in your ear is almost conversational, but for the sadistic glee dripping from his words. "Let's watch." He presses your head, forcing you forward. It's step towards the pit or be slammed directly onto your face, and soon you're once again overlooking the Project. Catalyst drags you to the ground, twisting an arm painfully behind your back, his hand @{(mc_hairlength = 3) on your head|in your hair} pushing you against the pit's bars.

A few eyes blink up at you with suspicion, jealously protective of its prize, but most of its attention is now on messily tearing its fresh-served corpse lunch to pieces.

Crunch.

Crunch.

*choice
    #Fuck. Fuck. Fuck. Fuck.
        *set expressive %+ 7
        Uneven, panicked breaths rush through your nose.
        
        You can't look away. You can't blink.
        
        The monster feasts, and Catalyst barely needs to hold you as you tremble, transfixed.
        
    #Squeeze my eyes closed.
        You slam the shutters, placing a paltry shield between you and the Project's mealtime.
        
        For a moment, you're foolish enough to think yourself safe, then Catalyst grunts in irritation.
        
        "I said let's watch. Open your fucking eyes or I'll peel 'em open myself."
        
        No choice. Never a choice. You open your eyes to the monster's feast.
        
    #This doesn't affect me. It does [i]not.[/i]
        Oh, $!{forename}, if only willing something made it so.
        
        You try to steel yourself. You try not to react. @{(expressive < 31) Stoic as you are, you very nearly succeed. Then, the sound of a half dozen greedy mouths permeates your defences.|It's a doomed effort, with a dozen greedy mouths feasting before you.}
        
        The memories flood in, sweeping away your resistance.
        
        You begin to tremble.
        
        *set expressive %- 10
        
    #@{untether Looks like I'm disconnecting again.|Disconnect.}
        *set checkedout true
        *set expressive %- 10
        
        Oh, what's that? You're looking for $!{forename}? Yeah, sorry, ${mc_he}@{mc_singular 's|'re} not here right now.
        
        You look without seeing, hear without listening, taking refuge in a quiet corner of your own mind.
        
        Huddling away from reality.
        
    #Whimper.
        *set expressive %+ 10
        The sounds trickle out of you, pathetic and desperate. Just seeing the Project is enough to send you reeling back to the past, the sound of a half dozen greedy mouths beginning their feast amplifies the memories threefold.
        
        Worse yet, you know that the sight of you shaking and whimpering is exactly what Catalyst wants.
        
        
Your cheeks are damp.

Catalyst chuckles, a deep rumble. "Our favourite housecat munching away. You sobbing like a little bitch. Ain't this nostalgic?" Catalyst grinds his knee into your spine, wrenching your shoulder even further back. "Reminds me how you'd used to cry about your poor little flare buddy. What was their name again? Prey?"

*if (checkedout)
    *if (brokenheart =2)
        No level of detachment is enough to inure yourself to him talking that way about Prii.
        
        *choice
            #Anger.
                Rage floods through you, a furious tide that snatches breath from your lungs and reason from your mind.
                
                How fucking dare he.
                
                *goto gutsnarl
            #Grief.
                Getting Prii's fate rubbed in your face is more than you can bear.
                
                Catalyst's callous taunt hooks into your heart, then begins to prise.
                
                *goto sads
    *else
        You can't sever yourself entirely. Perhaps the taunts take longer to permeate, but eventually they seep through to your mental sanctuary.
    
*elseif ((bestie = 2) or (prev_li = "Prii"))
    Your jaw clenches. Bastard.
    
*else
    Oh he did not.
    
*choice
    #It's just words. Don't let him goad me.
        Prii's gone. Catalyst mocking them stings, but he's just trying to get under your skin. If you don't take the bait, you're coming out ahead.
        
        *if instinctive > 45
            That's cold logic. A little difficult to heed when every part of you is screaming to tear off his head.
            
            Through some herculean effort, you manage to ride out the urges and avoid losing your shit, swallowing your fury, so potent it almost burns away the unease of the Project's feeding frenzy below.
            
        *else
            That's cold logic. Usually it's your forte, taking things slow and steady.
            
            Even your cool head is frothing with barely-suppressed fury. It's far from easy to fight back the urge to just go nuts on him, even with the Project's feeding frenzy below to temper your anger.
            
        As it becomes clear you're not going to react, Catalyst gives a quiet 'hmph'. "Guess it was Prey." He forces your head even harder against the metal.
        
        You offer them a silent apology, and can almost hear Not-Prii's answering snort.
         
        *goto interrupting
    *selectable_if (checkedout) #@{checkedout And? I checked out five minutes ago.|I can't separate my emotions from this,}
        *set instinctive %- 10
        He may as well be talking to a wall.
        
        The emotions don't matter if you've excised the person that should feel them.
        
        Still and silent, you cast yourself as someone other from the ${mc_guy} with ${mc_his} head pressed against the metal bars.
        
        There's no bite to Catalyst's barbs. He's talking about a stranger.
        
        *goto interrupting
 
    #Rip myself free and kick his ass.
        *set instinctive %+ 10
        *if coven_history = 1
            The urge is there. You picture yourself fighting back. Giving him what he deserves.
            
            And then he hurts you. Or puts you back in the dark place. Both at once, probably.
            
            You tremble, a sickly sensation trickling down your spine. Fighting always makes it worse. Always. Always. Always. Always. Always—
            
            *choice
                #It's not about me. Do it for them.
                    *set defiance +1
                    You refuse to let him mock Prii.
                    
                    You [i]refuse.[/i]
                    
                    *goto gutsnarl
                #I... I can't.
                    Pathetic. Coward. Gutless.
                    
                    All these recriminations and more you pile upon yourself, and still you cannot compel yourself to move.
                    
                    Not even for Prii.
                    
                    *goto interrupting
            
        *else
            *label gutsnarl
            *set scrapcat true
            *set defiance + 1
            *set rel_catalyst +1
            *achieve workbeef
            
            With a guttural snarl you tear yourself from Catalyst's grip, throwing back an elbow in an effort to dislodge him. Off guard, he loses balance, and you slither out from underneath him, scrambling to your @{(guts > 40) feet and throwing a wild overhand that glances from his jaw.|feet—}
        
            *if guts > 40
                Catalyst staggers, then snaps to awareness, a crazed grin lighting up his face like a pinball machine. "Oh! We doing this now!? @{(coven_history = 1) Been a fucking while since you stood up to me!"|You finally find your fucking spine?"}
                
                @{(coven_history = 1) Your breath catches, but you're not letting fear get the best of you, not this time.|You clench your fists. Yeah. Maybe you fucking did.}
                
                He launches himself at you. With a smart step back and a warding forearm, you fend him off. Ducking his next swing—whistling overhead—you rake his shin, then land a solid punch to his gut. Attempting to follow through, you're thwarted by an explosive roundhouse kick that just barely grazes you as you hop back at the last second. Trebled, that would have put you on the floor.
                
                Still grinning, Catalyst beckons with both hands. You oblige, parrying a punch to get right up in his space, clinching him around the neck to start driving knees into his abdomen as you struggle and jockey for position—
            
            *else
                —and instantly eating a punch square to the jaw, knocking you straight back to the ground, the echoes of the hit bouncing your skull off the concrete. Twice. Before you can stand, Catalyst is on top of you, elbowing you in the head for good measure. One two three.
                
                "Aw, did I hurt your fweeings?" He laughs, hot, stale breath blasting in your face. "Too fucking bad—" You headbutt him, knocking him askew, then sending him the rest of the way with a punch. You lurch upright, skull ringing with the repeated impacts. Barely you block as Catalyst swings for your head, the hit and its mirrors numbing your forearm. He deflects a low kick easily, snatching a fistful of your shirt and cocking back his fist— 
                 
        *label interrupting
        @{scrapcat "Are you morons seriously fighting in here?"| "Am I interrupting something?"}
        
        Lullaby's nonchalant drawl @{scrapcat halts you both in your tracks.|drifts over from the entrance. Catalyst's grip loosens just enough for you to look in their direction.} They're leaning against the bulkhead door, arms crossed and sunglasses lowered.
        
        @{scrapcat "Shove it up your ass," Catalyst growls. "Dime needs showing ${mc_his} place."|"Yeah, actually," Catalyst growls. "So fuck off."}
        
        @{scrapcat "And it couldn't wait until you were out of the Project's room?" They tap the doorframe with a foot. "Which, I should add, you didn't close behind you."|Lullaby's mouth slowly curls into a smirk. "Well. I won't be doing that. I'm here to fetch you, since you seem to be done feeding the Project." They hook their thumbs into their coat pockets, smirk evolving into a sly grin. "Much as I hate to interrupt your special time with Dime."}
        
        Catalyst @{scrapcat glares murder at them, then shoves you away and spits on the floor.|drops you like you're on fire, clanking your head off the bars. You manage to stop yourself sliding into the pit, watching dazedly as Catalyst begins advancing on Lullaby with slow, methodical steps.}
        
        @{scrapcat "Charming."|"Say that again, and I don't care how valuable you are, I'mma tear your throat out," he says, voice low and dangerous.}
        
        @{scrapcat "Get fucked, Lullaby."|"Mm, yes, and remind me, what did Hypothesis do when you screwed up his operations before?"}
        
        @{scrapcat They roll their eyes. "Yes yes, you hate my guts. Now come along before Hypothesis grows impatient. I presume you remember what happens when you get on his bad side?"|}
        
        Reflexively, Catalyst's hand goes to his neck, where an almost-black mark encircles it in a ring. 
        
        *if (scrapcat)
            
            *choice
                #I'm still furious. I'm taking a swing the second I get the chance.
                    You're keyed up and out for blood, Catalyst's mockery buried in your mind like a fish hook. As they argue you edge closer and closer, staying in Catalyst's blind spot.
                    
                    Closing to within a couple of steps, you catch Lullaby's attention. Their eyes flick from Catalyst, to you, and back, and they subtly shake their head in warning.
                    
                    *choice
                        #Actually, this is a bad idea.
                            While you hate giving Lullaby the smallest piece of credit, your second thoughts are a lot more rational than their predecessors. Fighting Catalyst is bad enough. Sucker punching him could legitimately get you killed.
                            
                            With every ounce of willpower, you swallow your rage and retreat before Catalyst notices where you're standing.
                            
                            *goto leavingproject
                        #Screw them. Hit Catalyst anyway.
                            *set suckercat true
                            *set rel_catalyst -1
                            *set instinctive %+ 10
                            The crack of your forearm into the back of Catalyst's skull is beyond satisfying.
                            
                            He stumbles, almost colliding with Lullaby, then pushes off from the wall and whirls around, face contorted in abject rage.
                            
                            "You're fucking dead," he hisses.
                            
                            There's a tight grin on your face as you raise your fists, ready for another round. Adrenaline pumps through your body, riding a roller coaster with no brakes. Catalyst's eyes bulge, a vein popping out on his forehead.
                            
                            You each lunge at the other, and each falter as a wordless melody echoes through the air. Your limbs are suddenly heavy, thoughts slowing to a crawl. Catalyst throws a limp punch, but his arm drops to his side before making it halfway.
                            
                            Lullaby sings another few notes for good measure. You sway, keeping your feet with considerable effort. Catalyst actually falls to one knee, then springs back up with a growl, more enraged than ever.
                            
                            "If you two insist on having it out, then kindly wait until after the meeting. I'm not arriving late because you can't keep your tempers," Lullaby says tersely.
                            
                            "Eat shit." Catalyst glares at you. "This isn't over," he promises. He stalks out, a little unsteady from Lullaby's power.
                            
                            Lullaby rolls their eyes. "Thank you for that, Paradigm. He'll be throwing fits for at least a month." They sigh. "Get going. I'll close up here."
                            
                            The soporific song has stifled your anger, and you slip away wordlessly. You've built up enough of a resistance to Lullaby that they can't knock you out immediately any more, but this close to them, the effects come on too fast to put up much resistance. 
                            
                            @{(defiance > 4) Eventually, you'll find a way. For Lullaby, for Catalyst, for all of them.|}
                            
                            *goto leavingproject2
                #My anger is bleeding off into dread. I've made a huge mistake.
                    Catalyst won't let this slide. He'll take the slightest excuse to beat you bloody, and you gave him a little more than that.
                    
                    As soon as Lullaby's done drawing his ire, it'll turn back on you.
                    
                    You're dead meat.
                    
                    *goto leavingproject
                    
                #It's barely a taste of revenge, but it's still satisfying to watch Lullaby shut Catalyst up.
                    *goto hiddengrin
                #I'm seething at Lullaby too. They're interrupting.
                    You were finally, [i]finally[/i] getting back at him, and Lullaby had to show up. @{(guts > 40) You landed a couple of good shots, had a slender advantage. That's never happened before. Ever.|Maybe you weren't exactly winning, but that barely matters. The act is more important than the outcome.}
                    
                    There's no point going for Catalyst again with Lullaby around; they'll just put a stop to it with their song. That's Lullaby, the contingency plan, the emergency brake, should anything go contrary to Hypothesis's plans.
                    
                    At least their interference is good for one thing. It confirms that if you want payback, you'll need to pick a battlefield beyond the Coven's reach.
                    
                    *goto leavingproject
    
        *else
            *choice              
                #I get a vicarious kick out of watching Lullaby push Catalyst's buttons.
                    *label hiddengrin
                    A hand to your mouth hides the grin. @{(coven_history = 3) You'd never be able to get away with sassing|You wouldn't dare to sass} him like that. Lullaby—vital for sedating the project—is the only one who can talk back to Catalyst without getting their face smashed in.
                    
                    Seeing Catalyst all riled up from Lullaby's jibes is pretty entertaining, even if @{scrapcat it can't compare to punching him in the jaw.|it's nothing close to actual payback.}
                    
                    *goto leavingproject
                #This makes me nervous. Lullaby's untouchable. I'm not.
                    You give Catalyst a wide a berth as you can while edging closer to the door. You're an easy—a favourite—target for Catalyst to vent his frustrations. He's taken an argument with Lullaby out on you before.
                    
                    Lullaby knows you're the punching bag and doesn't care. Nobody's going to look out for you but you.
                    
                    Thankfully, whether by luck or your efforts to stay out of sight and out of mind, Catalyst doesn't spare you a glance, stalking to the door and barking "Move."
                    
                    *goto leavingproject1
                #And by 'before', Lullaby means that night. Hide my grimace.
                    Catalyst is the reason you and the others made it as far as the Project. The watchman who failed his watch.
                    
                    You don't know why he wasn't where he was supposed to be. It's not like you can ask him.
                    
                    His mistake. Your suffering. His own too. Difficult to care about that.
                    
                    *goto leavingproject
                    
    #Despite my best efforts, I'm verging on tears.        
        *label sads
        From a trickle to a flood, you begin sobbing.
        
        There's no justice here, no heroics, no knight in shining armour. You couldn't save Prii. You can't even defend their memory. You can't even stop yourself giving Catalyst the [i]satisfaction.[/i]
        
        His mocking laughter rings in your ears while you drown in anguish.
        
        *goto interrupting

*label leavingproject
"Whatever," Catalyst growls, stalking to the door. For a second, he looks like he's going to lunge for Lullaby, but then he simply grinds out a "Move."

*label leavingproject1
Lullaby makes a mockingly elaborate show of presenting him with the exit, sweeping into a bow as they step aside.

If looks could kill—or if Catalyst was that one villain with lasers for eyes—Lullaby would be smouldering ashes. He stomps out, leaving you to cautiously approach.

@{scrapcat "That's probably going to cost you," Lullaby observes, detached. "Hope you got your money's worth."|"I'll close up. You're welcome," Lullaby drawls.}

@{scrapcat You bite down on a response. They're just the peanut gallery, and surely don't care either way.|You mumble something in the zip code of a 'thanks', solely to stop them making it your problem if they're feeling capricious.}

*label leavingproject2
Heading back into the corridor, you navigate as best you remember. You've rarely had free rein to wander the building, so you don't know your way around as well as you could.

Still, if need be, you can just follow the sound of Catalyst's thumping steps.
        
*page_break Make your way.
*if (scrapcat)
    *achieve bitingback
        
If you were to hazard a guess, the Coven congregation point used to be a boardroom. It's a bare rectangular space crying out for a long table surrounded by briefcase-wielding, suit-wearing executives.

Instead, there's a handful of your 'colleagues' scattered around, each of them visibly tense. Catalyst leans on the wall, arms folded, getting a wide berth from everyone. Hypothesis, who arrived shortly after you, has taken up position behind a raised lectern. While all conversation ceased upon his arrival, he'd simply waved the group to carry on. Hypothesis brought a small case with him, and has laid it on the lectern to open up, though you can't see the contents from this angle. It's similar in appearance to your Juice container, albeit larger. You're certainly not approaching to get a better look.

$!{cg} entered alongside Hypothesis and promptly wedged herself in a corner. Her expression is closed off, eyes watchful.

"Paradigm! Long day? You're looking pretty tired there, buddy."

@{(instinctive > 40) You|You manage not to} startle as Variable pops up out of nowhere—were they hiding behind the damn door?—grinning blithely. @{ariattitude While you're deeply not in the mood for them, you've no choice but to|Too late to duck them now. You|There are days you're more equipped for their brand of enthusiasm than others, and today is not one of them. Nevertheless, you|Ugh. You steel yourself to humour their overbearing enthusiasm and} acknowledge them with a nod.

@{(expressive > 40) "Long day," you confirm.|Hopefully they take it as an answer too.}

Cheerfully, they bluster on, oblivious to your apathy. "Me, I've had the craziest time. Guess what happened after you left Masquerade."

*choice
    #"I'm not in the mood for guessing games."
        If it actually matters, then they can use their words.
        
        *goto noguesses
    #"No idea."
        Perhaps one day they'll pick up the hint.
        
        *label noguesses
        "Aw, not one guess?" Variable wheedles.
        
        You fold your arms.
        
        They huff in disappointment. "You're no fun, Dime. Fine, fine. I'll tell you."
        
        *goto scumdetails
    #"I don't know. Gatecrashers."
        Variable looks slightly put out. "Aw, you already heard?"
        
        You blink. "No?"
        
        "But you said—" They stop, and then grin. "Ohh! Good guess! I mean yeah, kind of!"
        
        *label scumdetails
        
        Well. This is the conversation you're having now.
        
        "See, later that evening, we get word from the bosses—the Businessmen bosses that is, not our [i]actual[/i] boss, haha—that they've spotted some shifty folks on the dancefloor. Turns out it's freaking [i]S.C.U.M.![/i] How nuts is that?"
        
        *choice
            #S.C.U.M.? Mention my own encounter.
                *set tellairy true
                Against the odds, Variable has your attention.
                
                "No kidding? I ran into them today too," you inform them.
                
                Airy's eyes bug wide. "Whoa! Like, just at random?"
                
                "They hit the café I was in for some reason," you explain.
                
                *label wildvariable
                "Wild!" It's Variable, so you don't have to second guess that their enthusiasm is genuine. "Maybe they're tailing [i]you[/i], Dime!"
                
                *label holdvariable
                Hold on.
                
                Could they be? Back at the café, Insider @{tag picked you out incredibly quickly.|certainly seemed to be zeroing in on you.}
                
                But… that doesn't make sense. Before today you hadn't had any brushes with S.C.U.M., so how would they track you down?
                
                *if (tellairy)
                    While you speculate, there's movement from the corner of your eye. $!{cg} has extricated herself from her corner to join you. Eavesdropper.
                    
                    "Oh hey, CG!" Variable calls. "Me and Dime were just talking about bumping into S.C.U.M.!"
                    
                    "I heard," she replies. "You're loud."
                    
                    They laugh. "You know it!"
                    
                    You're pretty sure that wasn't a compliment.
                    
                    
                @{tellairy Regardless, $!{cg}|$!{cg}} looks speculative. You don't blame her. While it was just a wild guess, if Airy's actually correct and S.C.U.M. have a way of locating you, that could be a problem.
                       
                *page_break
                *goto endairyconvo
            #Crack a joke about my encounter.
                *set tellairy true
                *if expressive < 31
                    *set expressive %+ 5
                    "I ran into them today too," you say. "I guess they're… coveen-ing."
                    
                    Variable blinks at you.
                    
                    "You know, like, Coven. And convening. Coveen-ing," you explain. Awkwardly.
                    
                    "Ohhhh." Variable smiles guilelessly, but doesn't laugh.
                    
                    Sadly, the room lacks any holes to crawl into.
                    
                *else
                    *set expressive %+ 10
                    "Yeah? I ran into them today too," you say. "I guess we're in a wretched hive of S.C.U.M. and villainy."
                    
                    Variable laughs. "That was [i]terrible[/i], Dime."
                    
                    "You laughed though."
                    
                    They do so again. "You got me there."
                    
                    @{(ariattitude = 3) It's moments like this that make you wonder if Airy is someone you could actually befriend. Then you remember where you are. Who they are.|Huh. You're actually getting along with them. Novel.}
                    
                "But back up a second, you saw them too?" Variable's eyes widen. "Maybe they're tailing [i]you[/i], Dime!"
                
                *goto holdvariable
            #Make a suitably impressed sound.
                "Mm?"
                
                Nailed it.
                
                *label cornermove
                Movement from the corner of your eye. $!{cg} has extricated herself from her corner to join you. Eavesdropper. 
                
                It says something about the day you've had that $!{cg} voluntarily involving herself in conversation with Variable doesn't even register on the strangeness scale. "S.C.U.M. attacked Masquerade? Dime and I had a run in with them earlier today too."
                
                *goto wildvariable
            #Shrug.
                *set expressive %- 10
                Sure, Variable's story is interesting to Variable, but Variable could get excited about seeing a stray cat. 
                
                It's just two enemy gangs butting heads, you don't see what that has to do with anything.
                
                *goto cornermove
            
    #"Happy hour."
        Variable grins. "Nope!" They pause, frowning. "Well, technically yeah, but that's not the thing I was asking you to guess. Half a point!"
        
        You were not aware there was a points system.
        
        *label variablecontinues
        "I'll just tell you," Variable continues. "No way can I keep it to myself."
        
        *goto scumdetails
    
    #"Management had a surprise birthday party."
        Variable laughs. "As if Management wouldn't schedule it all in everyone's diaries! I've never met someone so fussy about paperwork!"
        
        You think they're kidding. Then again, it's Management. You wouldn't put it past her.
        
        *goto variablecontinues
    #"Glamoura showed up and torched the place."
        Variable laughs. "Dime, come on! Glamoura's been gone at least a year. Smashing up a nightclub's way too small time for her."
        
        Eventually, the small surprises will run dry. Eventually, you'll take a bottom step and find ground, instead of empty air.
        
        *goto variablecontinues
    #Don't answer them.
        *set expressive %- 10
        They wait several seconds longer than any normal person would. You stand firm.
        
        *goto noguesses
    
    
*label endairyconvo
The conversation comes to an abrupt end as Lullaby steps through the doors and Hypothesis straightens from the lectern.

"Hello, Lullaby." Though he's speaking softly, his voice silences the room. "Now that you're here, we can begin."

They bow ironically, then amble to an open space.

Hypothesis touches a button on the lectern, leaning close to a microphone. "Gremlink, Security check, if you please."

Despite being on the far side of the room and the opposite side of a radio, Gremlink's voice is loud and clear. [i]"All good over here boss. Got my eyes peeled and the lookouts are where they should be."[/i]

"Excellent. Carry on."

[i]"Youuuu got—"[/i] 

Hypothesis clicks off the intercom. His gaze takes a slow crawl across the crowd. You hold your breath, but he passes over you without slowing.
        
*page_break Then, he begins.
        
"Thank you all for coming." As if there was an option to decline.

Again, Hypothesis's eyes trail over his audience.

"My Coven," he says softly. "A curious title, is it not? I imagine the thought has crossed the minds of everyone here: why did I name each of you for scientific principles, yet the group for backward superstition?" He pauses for effect. "The simple answer is misdirection. Were word to leak of our operation, its title would evoke thoughts of a gaggle of fools muttering incantations around a cauldron. In short, the very opposite of this group."

His lips peel into a cold smile. "I should hope that I have taught you all not to accept the easy answer at face value. While the notion of camouflage has merit, the truth is more complex. More… personal." 

Around you, the Coven reacts. Some faces are surprised, others, excited. Variable leans forward with rapt attention. $!{cg} frowns, though you can't say whether it's in consternation or deep thought. Lullaby looks bored, Catalyst like this is the most important speech he's ever heard.

"Your abilities contradict the conventional understanding of parahumanity. One gains powers under great duress, or via technology, or inherits them. Not through some 'magical potion'. And yet." Hypothesis's smile is gone. The chill remains, and grows. "Your very existence is proof that the foundations of this so-called science are no more grounded than the folklore of witchcraft and sorcery. And we are to accept 'people develop powers at random, don't ask why it only happens for some' as fact? We are to accept 'well, the child of a parahuman gets powers sometimes, but not always, with no clear genetic markers'? And augments?" He grimaces, as if the words taste foul in his mouth. "We place cybernetic enhancement in the same category as these other abilities? On the basis of also having the capacity to prance around in bright costumes punching one another? Absurd."

He drums his fingers on the lectern.

"This group is named Coven because it is just as spurious as these commonly held 'facts'." His drumming ceases, hand clenching. "I am a man of science, and I refuse to accept that world-changing, life-defining abilities are governed by [i]chance[/i]. There is a truth to all of this, and I will find it."

*choice
    #Listen and pay attention.
        Hypothesis isn't done talking. @{(defiance > 2) Best you look the part.|It's important you hear what he has to say.}
        
        @{(coven_history = 3) Play the game, and all that.|Nor is it ever a bad idea to keep your head down.}
                
    #He has a @{(defiance > 2) point, much as I hate to admit it.|point.}
        The Juice very clearly breaks the rules. You've had the thought yourself. It makes everything else about parahumans seem significantly more shaky, and even deeming Juice as artificial, same as augmentation, there's nothing they have in common. Juice is biological, not technology.
        
        Just because a theory is popular doesn't mean it's right. What else does Hypothesis know, that he isn't saying?
        
    *selectable_if (knowledge > 40) #Consider his speech through a scientific lens.  
        Your knowledge on parahuman theory is very rusty, and it's a moment before you bring anything pertinent to mind.
        
        He's more right than he is wrong, though he's also glossing over some of the details. For one, augments as parahumans comes from the DPR's definitions of the term; the science focuses much more on the incompatibility of augmentation with other powers, a mystery you assume remains unsolved over the last five years. For another, the occurrence of second generation parahumans is far above the population average. Being unable to find the genetic markers for inheritance is not the same as those markers not existing.
        
        On flares, Hypothesis has a point. The igniting process is especially poorly understood, and you recall many an unanswered question. How can a person suddenly light up like a supernova, regardless of their abilities? Why does every ignite begin in the same way? Why does it never happen again? Why is it seemingly impossible to find any traces of a dormant power?
        
        You should probably check if the science has advanced on any of those questions during your captivity. You suspect not.
        
    #What does he mean it's personal?
        Somehow you doubt that this boils down to a scientific dispute. Surely Hypothesis's driving force can't be as petty as someone's paper getting accepted over his own.
        
        You don't start a secretive, illegal organization just because your academic rivals pissed you off.
        
        …Right?
        
    *selectable_if (observation > 40) #I've been looking for tells. Does he believe what he's putting down?
        As Hypothesis speaks, you steel yourself to focus on his face, feeling your pulse accelerate with the tension of staring straight at him.
        
        Little strikes you as out of place. There's no hesitation, his eyes don't flicker, and his body language reads as normal. He's being theatrical, but you don't think he's lying.
        
        Even so, here and there, Hypothesis's eyes go distant, as if his mind isn't entirely in the room. When he calls the truth more personal, again when he mentions chance, you have a feeling he's thinking on something specific.
        
        What could that be?
        
    #Sounds to me he's on an ego trip.
        *set defiance +1
        Hypothesis isn't championing the noble cause of truth, he just wants to prove others wrong. His 'formula', the Juice, causes the development of parahuman abilities, so that makes him better than anyone else.
        
        Clearly the Juice works. If he wants to advance science by correcting the mistaken assumptions about parahumans, then he's taking his sweet time telling anyone.
        
        @{(expressive > 60) You're calling bullshit.|Somehow, you're sceptical of his claims.}
        
        @{(coven_history = 3) The thought of undercutting him in front of the group nearly gets you smiling. Too bad it's only a daydream.|A greater part of you than you'd like tenses just thinking something so mutinous. The paranoia that he'll know what you're thinking is lodged deep.}
        
    #An old tormentor bubbles to the front of my mind. Why did they ignite, and not me?
        *set contemprii +1
        The situation was identical. Two injured friends. A ravenous monster. 
        
        You were all there together.
        
        They blazed with light. You remained in the dark.
        
        *if ((prev_li = "Grant") or (prev_li = "Shauna"))
            The feelings you held for @{(prev_li = "Grant") him|her} shouldn't have been second to theirs. How could they care about @{(prev_li = "Grant") him|her} more than you? Did it not hurt enough?
            
        *elseif ((bestie > 2))
            That was your best friend in danger. How could they care about @{(bestie = 3) her|him} more than you? Did it not hurt enough?
            
        *else
            Did it not hurt enough? Did you not care enough?
            
        Were you not good enough?


Hypothesis is letting his last statement hang in the air. You aren't used to seeing him in front of an audience, and it's a far cry from the clinical detachment of the lab.

Regardless, something must have shifted. Hypothesis wouldn't gather the entire Coven on a whim.

Finally, he resumes. "The next step in our work has been a long time coming. We have encountered setbacks" —his eyes linger on $!{cg}, then Catalyst, who fidgets uncomfortably— "which have mandated that we correct course. Despite this, we persevered, and now I have made a breakthrough."

The room ripples. Catalyst is staring at him with something like adoration. $!{cg} squeezes hard at her own forearms, an indecipherable conflict playing across her face. Even Lullaby turns their head. Breakthrough isn't a word Hypothesis uses lightly.

*page_break He's smiling again.
Hypothesis turns the little black case around with a flourish. Nestled within are a half dozen vials, identical to your regular doses of Juice.

The liquid they contain, however, is not.

Usually, the Juice is almost neon. These vials' contents are a deep purple, their glow swallowed up in the darkness of the hue.

"A refinement to the formula," Hypothesis proclaims, luxuriating in his Coven's awe. "With this, its effects shall grow more potent than ever before."

The case has its own gravity, inexorably pulling your eyes toward the cluster of vials. New strength. A new toll to pay.

*choice
    #I'll take more power wherever I can get it.
        *set content +1
        You need to be at your full potential. You have too many enemies for anything less. What if the Altruists learn who you are, and you're forced to take them all on at once? What about the next showdown with the Hounds?
        
        @{(defiance > 3) What if you choose to break these shackles of yours?|Besides, you're already on the Juice.}
        
    #This bargain has always been tainted. What's another string?
        *set trade +1
        
        It doesn't matter if this enhanced Juice is more addictive, if the withdrawals are more painful. Fast or slow, agonising or peaceful, the consequences remain the same, the chalice just as poisoned. Drink the Juice, or die.
        
    #I'm sick to my stomach. I was foolish to think I'd hit rock bottom.
        *set hate +1
        When will enough be enough? You're infested, rewired, puppeted like a marionette, and still he invents new ways to keep you trapped beneath his thumb. More potent Juice, more power to each and every one of your captors.
        
    #If only these powers came without a catch...
        *set trade +1
        *set defiance +1
        
        Envy fills you. Regular masks don't know how good they have it, to possess abilities that don't chain them to a master, nor mark them with a slow death sentence. There's so much you could do, would do, if your powers actually belonged to you.
        
    #How strong is strong enough to break these shackles?
        *set content +1
        *set defiance +1
        
        You allow yourself the brief indulgence of imagining how it would feel to beat Hypothesis into a paste with the same powers he gave you. Then, you lock those thoughts up tight, lest they stab you in the back. @{(defiance > 3) You'll have your day. You—you will.|And wonder where they came from; such defiance isn't like you.}
        
    #'More potent'? Tighter leash, more like.
        *set defiance +1
        *set hate +1
        You can already feel the weight around your neck, the replacement of your chain with an even heavier counterpart. Hypothesis wouldn't bestow additional power on anyone unless he was completely confident he could control it. There's no boon here, only ever deeper servitude.

After an appropriate interval for everyone to stare at the vials, Hypothesis continues. "Do not be mistaken. The improved formula is not an invitation to recklessness or to compromise our secrecy. We will move forward as we have done for years: with due care and consideration. Given the groundwork so painstakingly laid by your combined efforts, it would be rank foolishness to lessen our standards within touching distance of success."

Another ripple through the audience. Nearby, $!{CG} has gone pale, stricken.

There's a gleam in Hypothesis's eyes. "Yes. Success." He pauses, lifting a single finger. "No. Not merely success: we are on the cusp of greatness."

He [i]grins[/i], and it's something you never want to see again.

"You can all expect updated orders shortly. I'll discuss your tasks with you @{introuble individually."|individually. Until then, you are dismissed."}

*if (introuble)
    
    A couple of the others shift, readying to leave. Most don't; Hypothesis hasn't dismissed you just yet.
    
    "Now then." Two words are enough to stop the movement dead. "There is one other matter." Hypothesis sweeps the room imperiously. Then, his eyes alight on you.
    
    Your rebellion comes home to roost. 
    *page_break
    Catalyst's spite can't come close to comparing with Hypothesis's ire. @{scrapcat That you still have the grit to fight Catalyst despite everything he's done to you is proof.|They're on entirely different levels.}
    
    Catalyst may hurt you, may torment you, but Hypothesis holds the keys to your cage. Your freedom, scant as it is, rests entirely on his mercy.
   
    And you defied him.
    
    @{coven_history It took years to build some semblance of self from the shattered pieces. What will be left of you?|All your work to prove yourself, undone in an instant.|It's been so long since you've let yourself get trapped in this position. You only wish you could forget what's about to happen.}
    
    "Paradigm here has been in the field lately. I entrusted ${mc_him} with an important mission." Hypothesis pauses, allowing that to sink in. He's talking [i]at[/i] you, narrating your crime to the others. "Now, I made it quite clear to ${mc_him} that I was to be informed of any developments involving ${mc_his} assignment and the Zone. Subsequently, Paradigm reported to Control Group that there was nothing of the sort." His eyes return to you. "Such disregard for my instructions is unacceptable, and warrants correction."
    
    @{coven_history You're cowering, shaking like a leaf. Away from the Coven, you let the consequences of defiance slip away. Like a child disobeying their parent, you let yourself believe that you could mislead them and escape punishment. Time and again, you're stupid enough to give them an excuse.|You're almost too shell-shocked to cower. You've done everything that was asked of you, you've followed orders, you've been [i]good[/i]. You don't know what possessed you to lie to $!{cg}, and it doesn't matter. You disobeyed, and now you face the consequences.|You hate that you're cowering, hate that he can have this effect on you. Most of all, you hate your own foolishness. You'd been so careful not to let your true intentions slip, and you squandered years of work on a lie that was always going to fall apart sooner or later. Now, Hypothesis will never trust you the same way again.}
    *choice
        #@{(coven_history = 1) Beg.|Take the punishment. It'll be worse if I don't.}
            *if (coven_history = 1)
                *label plead
                "P-please, don't," you plead, breath dissolving into desperate gasps. "I'll-I'll do better. J-just don't hit me, please, please—"
                
                "Ssh, ssh, ssh," Hypothesis hushes. "This is a lesson, Paradigm. You're not giving me a choice, I'm afraid."
                
                You stop speaking.
                
                You continue whimpering.
                
            *else
                You stare at the floor and wait. Nothing you say will change what's about to happen, only encourage it.
            
            *set punish 4
            *set defiance -2
            
            *label beatdown
            *set punishjank true
            *page_break
            Catalyst is first. Catalyst is always first. He scythes your legs out with a kick—you're already on the ground before two and three—then drives another into your back. Another, another.
            
            All nine impacts rock your body, sending you writhing
            
            "Catalyst. Don't get greedy."
            
            With one—two three—more vindictive kick, Catalyst steps back.
            
            "Abstract."
            
            Your heart clenches with dread. It's that kind of punishment, then.
            
            Another figure approaches, lines up their leg, and kicks you in the stomach. @{(surpass_stomach > 2) A scream claws from your throat, clutching at your unhealed wound.|}
            
            *if surpass_stomach > 2
                "Oh? Are you injured, Paradigm?" He's detached, like this barely warrants his attention. "How unfortunate. Variable."
            
            *else
                "Variable."
            
            They shuffle across. "Sorry…" they mumble, then plant a boot into your kidneys.
            
            "Empirical."
            
            You stop hearing words, smearing into a white noise of pain and blood rushing through your veins.
            
            The assault abates. You choke on a sob. Someone is standing over you, and they're hesitating.
                
            "Go ahead, Control Group." Hypothesis sounds like he's at the bottom of a well.
                
            You can't even brace. Your body won't cooperate.
                
            *if rel_cg > 65
                *set intervene true
                The blow doesn't come.
                
                "$!{mc_he}@{mc_singular 's|'ve} had enough." $!{cg} is barely murmuring, but it carries.
                
                "That is not your decision to make."
                
                "$!{mc_he}@{mc_singular 's|'ve} had enough," she repeats.
                
                You manage to tilt your head upwards. $!{cg}'s looking down and away, shoulders hunched.
                
                "Control Group." A sharp note in his voice now.
                
                A pause. $!{cg} shakes her head.
                
                Hypothesis sighs. "I'm disappointed in you."  
                
                $!{cg} flinches a split second before Catalyst's fist smashes into her face. Before she even hits the ground, he rounds on you and picks up where he left off, kick after kick after kick.
       
            *else
                The kick lands. It hurts, but not much.
                
                She held back.
                
                "Catalyst, finish up."
                
            Each breath drags daggers over your chest. You taste blood. Your whole world narrows to the tip of a boot.

            Again and again, unrelenting, unbearable. @{(terminate > 0) Is this the end, at last?|Is he trying to kill you?}

            "That will do."
            
            *if (scrapcat)
                He doesn't stop. Again, again, again— 
                
                "Catalyst, I said [i]enough![/i]"
                
                With a twisted snarl and one final kick, he subsides.

            *page_break one two three
            Your body is a tapestry of pain as you gasp for air, vision swimming in and out of monochromatic existence. Black liquid drips from your mouth, and you can't tell whether it's your power leaking free or internal bleeding.
            
            This won't kill you. The Juice will see to that. You're not afforded the luxury of dying.    

            Arms clutched around your battered frame, you @{intervene register $!{cg} pushing herself off the floor. Her hand slowly moves up and down her cheek, eyes dull.|roll pathetically onto your side.} Hypothesis must have dismissed the others, because they're slowly filtering out of the room. None spare you a glance, flowing around you like water.
            
            @{intervene "We'll have words later, Control Group. Get out."|"Paradigm. Get over here. And don't drag your heels. You've tested my patience quite enough."}
            
            @{intervene Moving robotically, she jerks the rest of the way upright. Her head twitches in your direction, and then she's gone.|Oh how you wish you had it in you not to whimper.}
            
            *goto hypopart2
                
        *if ((coven_history = 1) and (defiance < 4))
            #Beg.[b]
                *goto plead
            #Beg.[i]
                *goto plead
            #Beg.[i][/i]
                *goto plead
        *else
            #With a good enough lie, I may be able to wriggle out of this.
                *if subterfuge < 25
                    *set punish 4
                    *set defiance -2
                    *set doubt_hypothesis + 5
                    You open your mouth, and the straw you clutched slips straight through your fingers.
                    
                    'With a good enough lie'. Yeah, and you became a competent liar when, exactly?
                    
                    The only fabrications coming to mind are hopelessly childish and paper thin. It's pointless even trying.
                    
                    *label stareatfloor
                    You stare at the floor, silently square your shoulders, and wait for the beating to start.
                    
                    *goto beatdown
                    
                *else
                    There's no point denying you were in the Zone—Hypothesis has you dead to rights—so you'll have to take a different tack.
                    
                    "I understand how this looks," you say, trying to stay calm. Or sound calm, anyway. "I assure you, there's an explanation. Why would I lie about something I knew you'd find out almost immediately?"
                    
                    Hypothesis weighs your words a moment. "Go on, then."
                    
                    "Architect plays his cards close to the chest. I knew he had something in mind, but I only learned the specifics after meeting with CG. From that point I was in the midst of the Altruists the entire time. There was no opportunity for me to inform you." 
                    
                    It's a flimsier pretence than you'd like. You're relying on your delivery to sell the story and on $!{cg} not to puncture a hole; you never alluded to an unspecified mission when you reported to her. 
                    
                    Hypothesis leans forward, ever-so-slightly. For what feels like hours, his crystal blue eyes fix upon you. Studying. Scrutinising.
                    
                    *if subterfuge > 50
                        *set punish 2
                        Then, almost imperceptibly, he nods. "A matter of unfortunate timing, then. Thank you, Paradigm." He narrows his eyes. "Of course, you agree that it's vanishingly unlikely that such a coincidence would happen twice, yes?"
                        
                        "Absolutely," you answer.
                        
                        "Very good." He addresses the full audience. "That will be all. Paradigm, stay here."
                        
                        As the room disperses, you glance at $!{cg} from the very corner of your eye. She could have made your life much harder, and she chose not to. @{cg_dislike What's her game?|You probably owe her a thank you.}
                        
                        *goto hypopart2
                        
                    *else
                        *set punish 4
                        *set doubt_hypothesis + 10
                        *set defiance - 3
                        Then he shakes his head, freezing your blood cold. "Paradigm, you should know better than to make excuses. I find it hard to believe that Architect would choose not to brief his allies, and harder still to accept you had not a single moment to slip away." He regards you over his glasses. "This was your top priority, Paradigm. Therefore, you are either lying, or failing to treat my instructions with the appropriate gravity. Either is worthy of punishment."
                        
                        You grope for another lie, another excuse. It all slips through your hands like sand.
                        
                        Too little, too late.
                        *goto beatdown

            #Make a rational appeal. I'm still embedded with the Altruists.
                Hypothesis is all about logic and reason. You don't need to talk your way out of your lie, you need to persuade him that punishing you is a bad idea.
                
                *if knowledge < 25
                    *set punish 4
                    *set doubt_hypothesis + 5
                    *set defiance -2
                    Which is the type of rhetoric you're fantastic at delivering. Since, oh, never.
                    
                    The straw you clutched slips straight through your fingers.
                    
                    All the arguments coming to mind are juvenile, reasoning that boils down to a collection of hasty excuses. Nothing that will move Hypothesis. It's pointless to even try.
                    
                    *goto stareatfloor

                *else
                    "I'm not going to make excuses," you say. "I withheld information, and I'll own up to it."

                    Hypothesis inclines his head for you to continue.

                    "My only request is that you don't lose sight of the bigger picture as I did." You let your shoulders slump. "I know how that sounds when I'm the one in the wrong. Even so, my task is ongoing. I'll already need to explain to the Altruists how I ended up getting dragged to the Hounds' building." — a murmur of surprise goes around the room — "If I show up injured, that's going to cause even more questions. I want to make up for my failure, not compound it." You do your best to sound calm, like rationality is in the driver's seat rather than desperation. "Please, don't allow my foolishness to compromise my mission further."

                    Hypothesis is quiet a moment, eyes alight with calculations. "So, to clarify. I should allow your transgression, because to punish you would cause a loss of credibility in your mission. Which you have demonstrably failed to carry out once already." A razor thin smile arrives and departs in a matter of seconds. "I almost admire the audacity, Paradigm."
                    
                    *if knowledge > 45
                        *set punish 5
                        *set doubt_hypothesis +10
                        *set punishjank true
                        You don't have an answer for that, and no answer is better than a bad one. You hold your tongue.
                        
                        Mercifully, it's the correct call, and Hypothesis continues. "However, I'll concede you do have something of a point." He raises a finger. "Assuming, of course, that you show no further lapses in judgement." 
                        
                        "Of course," you say, contrite as you can.
                        
                        Hypothesis nods briskly. "Then we will keep this to simply a reminder. Catalyst, please remind ${mc_him}. Leave ${mc_his} face alone, that's a good lad."
                        
                        Wait—
                        
                        *if surpass_stomach > 1
                            Catalyst's fist rams into your stomach and you cry out in agony, collapsing to the ground, hands clutched to the unhealed wound. You writhe as the aftershocks hit, curling into a ball, damp warmth blooming around your fingers.
                            
                            He laughs, sounding almost surprised. "I guess you hurt yourself fucking around, huh Dime?"
                            
                            Your only response is a wet sob. Catalyst laughs again.
                            
                            "That will do," Hypothesis says.
                            
                            *if (scrapcat)
                                *label nostops
                                And Catalyst slams his boot into your head, shattering sight into broken glass.
                                
                                [i]two three—[/i]
                                
                                "I said that [i]will do[/i], Catalyst!" Hypothesis snaps.
                                
                                Catalyst is a sneering, snarling blur as he steps away.
                                
                            *else
                                *goto fightthroughpain
                               
                            
                            *label fightthroughpain
                            By the time you're able to @{scrapcat see straight again,|fight through the pain,} the room has long since cleared, leaving you alone with Hypothesis.
                            
                            "Get up," he says disinterestedly. "We have more to discuss."
                            
                            *goto hypopart2
                            
                        *else
                            Catalyst's fist rams into your stomach—one two three—folding you in half. Wheezing on the ground, you're defenceless against the swift series of kicks he drives into your torso and abdomen. You rock with every impact, each kick coming before the echoes of its predecessor are done.
                            
                            [i]nine ten eleven twelve—[/i]
                            
                            *if (scrapcat)
                                "That will do," Hypothesis says.
                                
                                *goto nostops
                                
                            *else
                                "That will do," Hypothesis says. You let a breath that's half sob as Catalyst finally stops.
                            
                            *goto fightthroughpain
                    *else
                        *set punish 4
                        *set defiance -3
                        *set doubt_hypothesis +10
                        You hesitate, struggling for an answer, then go for it anyway. "I understand the importance of—" 
                        
                        "Be quiet." You shut up. Hypothesis continues. "If you are so concerned about your mission, Paradigm, you would have followed instructions to begin with. No. This is simply an attempt to evade rightfully due consequences."
                        
                        The sentence is rendered. Nothing will change his mind now.
                        
                        *goto stareatfloor
                
            #Throw myself on Hypothesis's mercy and grovel.
                *set defiance -3
                *set doubt_hypothesis - 5
                *set trust_cg - 1
                *set rel_cg - 10
                *set punish 3
                
                Hypothesis wants to make an example out of you. It's both a show of control and a demonstration of consequences.
                
                So you just have to give a better show than the public beating Hypothesis doubtless has in mind.
                
                Hope you like the taste of shoe leather.
                
                You drop to your knees, then press your head to the floor. "I have no excuse. I'm ashamed of myself for what I've done." You project your voice good and hard, ensuring that it's not muffled by the floorboards an inch from your mouth. "You trusted me as an operative and I let you down, Hypothesis. I compromised our goals for selfish reasons." You shuffle a little closer to Hypothesis, then push your forehead even harder into the ground. "I can only beg forgiveness and a second chance, even if it's more than I deserve."
                
                Seconds tick by in tortuous silence. Tick. Tick. Tick.
                
                A soft laugh. Then Hypothesis's voice. "Take note of this, everyone. Paradigm erred, but ${mc_he} @{mc_singular knows|know} ${mc_his} place." Tap tap tap, his foot on the ground. "Just this once, I will trust that punishment is unnecessary. Get up."
                
                Tentatively, you raise your head. The eyes of the entire room are on you, burning you with humiliation. Catalyst looks disappointed, probably because he didn't get the chance to hurt you. $!{cg}'s eyes meet yours, and then she looks away sharply, face clouding with disgust.
                
                "Thank you," you mumble.
                
                Hypothesis flicks a hand at you dismissively. "Do not fail me again, Paradigm." He returns his attention to the others. "The rest of you may leave."
                
                You scrape yourself and what's left of your dignity off the ground as the Coven filters out of the room. Everyone gives you a wide berth. Can't let your failings rub off on them.
                *goto hypopart2
    
*else
    The room begins to move, bustling like a class packing up for their schoolteacher. You back up a step, start to turn—
    
    "Paradigm." His voice cuts through the crowd. Reluctantly, you halt. "Stay back."
    
    A carousel of potential transgressions whirls through your mind. @{scrapcat How could he have heard of what happened with Catalyst already?|Real or false, your imagination does the work.} The dread only builds as the room empties out, and the little thumbs up plus awkward smile combo Variable gives you on the way past does nothing to help.  
    
    Before long, it's just you and Hypothesis.
    
*label hypopart2
@{punishjank Painstakingly, you force your body into motion, dragging yourself off the floor. Hypothesis looks on with mild impatience as you finally manage to stagger upright and wobble your way over to him.|You venture closer to him, head lowered, not risking eye contact.} He gazes into the case of vials, still open in front of him, then at last turns his gaze to you.

"You've been embedded with the Altruists a good while now." Seems he's burned through his supply of pleasantries. "Tell me what you have @{(inform1 < 5) learned. Particularly about the Zone."|learned."}

*if (punishjank)
    *choice
        #I'm babbling almost before he finishes asking. Another punishment—I can't— 
            The events in the Zone facility and your subsequent scuffle with the Hounds come spilling out of you in a disjointed mess, your tongue tripping over itself in your haste to convey as much as you can as quickly as possible.
            
            Hypothesis holds up a hand. "Slow down," he tells you, irritation seeping into his voice.
            
            *goto describethings         
            
*elseif ((inform1 < 5) or (introuble))
    *choice
        #He already knows I was in the Zone. Pointless to try and play coy.
            *set inform2 1
            *if doubt_hypothesis > 10
                *set doubt_hypothesis -10
                
            *else
                *set doubt_hypothesis 0

            *label describethings
            *set inform2 1
            @{punishjank Your panic freezes. You start over, babbling less, describing|You give an unadorned rundown of what you encountered in the facility, as well as your scuffle with the Hounds. You describe} the unearthed doorway, the tunnels, the strange fog, the abandoned research room you found, and what it contained. Hypothesis stops you here and there for clarifications, scratching away at his notepad. The sound of his pen marking paper sets your teeth on edge, scraping at your nerves.
            
            Not-Prii, you keep to yourself. Even @{punishjank falling over yourself to please him,|} the thought of explaining that to Hypothesis makes you sick to your stomach. 'Oh, remember the person you fed to the Project, and I got some of their powers? Yeah, I saw their ghost'. 
            
            Hypothesis killed Prii. @{punishjank That burns deeper than your fear.|You couldn't tell him if you tried.}
            
            *if infocounter > 2
                *set covenstr +3
                
            *else
                *set covenstr +2
                
            Once it's apparent you're done, he nods slowly. "Most intriguing," he murmurs.
            
            @{punishjank Terror's cold fingers wrap around your heart and squeeze. That's ambiguous. Did you not say enough? Should you keep going? Will he—he's nodding.|You nod briskly, attempting to ignore the churning guilt making its home in your gut.}
            
            @{punishjank He meant it positively. You're okay. Dizzy, you nod back.|}
            
            *goto hypodiscusscg
        #I'll pick and choose what to tell. He doesn't know what I saw.
            *set inform2 2
            *set covenstr +1
            With some strategic deployment of the facts, you can give the impression that you're sharing a lot more information than you actually are. Stretching things out should give you more space to breathe. @{coven_history Sure, your stomach roils unpleasantly at the prospect, but play your cards correctly, and you'll put a layer of insulation between you and your next deadline.|It's, admittedly, an aversion of your standard following-orders approach, but sometimes you have to look out for number one.|It'd be preferable not to tell him anything, of course, but you'd be playing with fire. Better to limit your big risks to when you have a concrete goal, rather than undermining him just for the sake of it.}
            
            So you pick and choose. You tell Hypothesis about the facility, and you focus heavily on the unearthed doorway, where it lay in the chasm, how you made it inside. You tell him about the tunnels, and you go into detail, pouring out all the minutiae. Just as you hoped, your thoroughness gets Hypothesis thinking, pausing in his notes to ask questions, delving into ever so granular information that you doubt will mean a thing in the long run. What does the layout of the tunnels and their collapses matter, when you're keeping back what you know of the abandoned research room?
            
            Not-Prii is something—someone?—you keep to yourself. You don't think you'd talk about them even if you were telling the entire story. Hypothesis owns their death as much as the Project.
            
            He doesn't get to know. Not that.
            
            Regardless, Hypothesis seems not to notice what you're doing. Maybe he's so desperate to hear about the Zone that he'll be satisfied with any scrap of knowledge. Maybe you've misjudged your scale of importance, and you're telling him exactly what he wants to know.
            
            Once you have concluded, Hypothesis nods slowly. "Good," he murmurs.
            
            Steeling yourself, you nod back.
            
            *goto hypodiscusscg
        #I feed him misinformation.
            *set inform2 4
            *set defiance +2
            
            Dangerous. Lies like this always come home to roost sooner or later. @{coven_history Part of your brain revolts at your intentions, and you're forced to quell those thoughts before even beginning to formulate a response.|Just as every time you venture outside your bubble of loyal obedience, your stomach flip-flops, anxiety mixing with uneasy, subversive excitement.|Nevertheless, it's no use ducking beneath the parapets if you refuse to emerge to take any shots, and this is one of your clearest opportunities yet.}
            
            There's plenty of Zone to discuss. It's straightforward to take what you saw and experienced and twist them. The mysterious fog you encountered becomes an active security measure, the research room is painted as just-recently abandoned, and in general, pure speculation is presented as hard evidence, Hypothesis stops you here and there for clarifications, scratching away at his notepad. The sound of his pen marking paper sets your teeth on edge, scraping at your composure.
            
            You don't touch the topic of Not-Prii. Even meddling with the details feels like too much. Hypothesis is as responsible for their death as the Project. He doesn't get your ghosts. Not even a reflection of them.
            
            *if (subterfuge < 40)
                Partway through your tale, Hypothesis's scratching pen pauses. His eyes lift from his notepad to your face. Assessing. Judging.
                
                He doesn't believe you. Hasn't believed you.
                
                A razor lodges in your throat.
                
                *if (guts > 20)
                    *set doubt_hypothesis +5
                    You swallow it down, and keep talking. You can't afford to stop. Lose your nerve, and you'll expose the deceit.
                    
                    As you continue your falsified summary, Hypothesis's expression shifts, and he resumes writing. You suspect he'll remain sceptical of what you've told him, but better sceptical than calling you to account.
                    
                    Concluding the retelling, you force yourself to meet his eye.
                    
                    He lowers the notepad and nods, ever so slightly. Steeling yourself, you nod back.
                    
                *else
                    *set doubt_hypothesis +10
                    Pinioned by that stare, your nerve fails you, and you falter, lapsing into silence.
                    
                    Hypothesis allows you to squirm for what feels like hours, stewing in the tension. He knows you lied, and that you've realised he has seen straight through you. Eventually, he puts you out of your misery. "You will report accurately in future," he says, quiet and measured.
                    
                    You're nodding before he finishes the sentence.
                    
            *else
                *set covenstr -1
                As you conclude your Prii-less, falsified tale, Hypothesis studies his writings, flipping back a couple of pages. After a few seconds he returns the notepad to a pocket, seemingly satisfied.
                
                "A most intriguing report, Paradigm. Well done."
                
                You hesitate, but detecting no trace of sarcasm, give him a quick nod. "Thank you."
                
                *goto hypodiscusscg
                
        
*else
    Obviously, you're not going to tell on yourself by informing him you went to the Zone. You're not stupid.
    
    *if archinfo = 0
        Problem is, you don't have anything else meaningful to say about your task; you're barren on the information gathering front. @{(defiance > 4) Well. 'Problem'. But his expectations won't change just because you don't want to fulfil them.|}
        
    *else
        You've uncovered a few things, even if they aren't all entirely concrete. Collectively, probably enough to sate his appetite. Individually, each a betrayal of your teammates' trust.
        
    *choice
        #Waffle about the inanities of the Altruists.
            *set inform2 5
            *set doubt_hypothesis +5
            Talking about a whole lot of nothing won't satisfy Hypothesis, but hopefully it'll keep you off the hook, at least temporarily.
            
            You begin, launching into a convoluted account of your experiences alongside the Altruists, rambling about the abilities each of them have shown. You backtrack, interrupt yourself, go into far too much detail on meaningless asides, and generally expend as many words as possible to say as little as you can.
            
            *if (expressive < 40)
                Hypothesis at first looks taken aback by this unusual bout of chatter, then his expression shades towards irritation.
                
            *else
                A look of exasperation swiftly descends over Hypothesis's face at your chatter. @{(expressive > 60) It's rare he gets the full force of your exuberance; you don't have the nerve.|}

             
            He holds up a hand to stop you. "Enough, enough," he almost-grumbles. He rubs the bridge of his nose, then lets out a sigh. "I expected something more substantive, Paradigm."
            
            "Oh, sorry." You don your best impression of blithe ignorance.
            
            "Don't apologise. Improve."
            
            You bob your head in an agreeable nod.
            
            *goto hypodiscusscg
        *selectable_if (archinfo = 0) #Admit I haven't made any progress.
            *set inform2 5
            *set doubt_hypothesis +5
            
            "There isn't anything worth telling," you say, apologetic.
            
            His brow furrows, followed by a slow shake of the head.
            *label nothingtosay
           
            
            *if ((libra < 5) and (libra != 1))
                "That's unfortunate." His eyes trail you up and down. "I would begin to question whether you are taking your responsibilities seriously, but Control Group informed me that you assisted her yesterday." He rubs the bridge of his nose, letting out a sigh. "I'm glad you understand where your priorities lie, but I must insist that you step up your efforts to extract information. I need results, Paradigm."
                
                *label glass
                Your throat fills with glass. A nod is all the response you can muster.
                
                *goto hypopart3
                
            *elseif (libra = 5)
                "That's unfortunate." His eyes trail you up and down. "I'm almost inclined to question your commitment, given how your group's interests clashed with our own yesterday." He pauses, a @{ontome blade|razor} poised at your throat. "However, Control Group informs me that it was unavoidable, so given the delicate circumstances, I won't fault you for prioritising your cover." He stares you dead in the eye. "Do better, Paradigm."
                
                Heart pounding, you manage a faint nod. Thank fuck that $!{cg} had your back.
                
                *goto hypopart3
                
            *elseif (libra != 1)
                "I must say, Paradigm, between this lack of progress and the troublesome incident with Control Group yesterday, I'm beginning to wonder if I was wrong to entrust you with this mission." His eyes pierce you, pinning you to the wall. "I expect results, and I expect you to assist Control Group where needed. You may consider this your final warning. Do better, or I shall cut my losses."
                
                *goto glass
            
            *else
                "That's unfortunate." His eyes trail you up and down. "I need results, Paradigm. Step up your efforts."
                
                You nod, trying not to look too relieved. That could have been far worse.
                
                *goto hypopart3

        *selectable_if (archinfo > 0) #Pretend I haven't made any progress.
            *set inform2 5
            *if subterfuge > 40
                *set doubt_hypothesis +5
                
            *else
                *set ontome true
                *set doubt_hypothesis +10
                
            "There isn't anything worth telling," you lie, affecting an apologetic tone.
            
            @{(subterfuge > 40) His brow furrows, followed by a slow shake of the head.|A razor-edged look almost has you recoiling. Almost.}
            
            *goto nothingtosay
        *selectable_if (liedetect = 0) #Explain I don't know anything I didn't already report to $!{cg}.
            *set inform2 6
            *set trust_cg - 1
            *set rel_cg %- 10
            
            "If you've spoken to Control Group, then you already know what I know," you tell him. "I haven't learned anything new since I spoke to her last."
            
            "I see. No matter."
            
            You nod cautiously, taken aback to be let off the hook so easily. Then again, $!{cg} probably won't appreciate you deflecting the questioning onto her.
            
            *if ((libra < 5) and (libra != 1))
                *goto unrelatednote
            
            *elseif (libra = 5)
                *goto trailingeyes
            
            *elseif (libra != 1)
                *label thenoteof
                @{(inform2 = 6) "Though on the note of Control Group,|"On a separate note,} I was troubled to hear of yesterday's incident involving you @{(inform2 = 6) both."|and Control Group."} His eyes pierce you, pinning you to the wall. "Allow to make this crystal clear, Paradigm. In future, if you encounter Control Group in the field, I expect you to assist her in any way she deems fit. Am I understood?"
                
                @{punishjank "Y-yes, of course. Absolutely!" you stammer.|"Yes, of course."} @{librafail Best not mention you didn't recognise her in the first place.|}
                
                *goto hypopart3
                
            *else
                *goto hypopart3
                
        *selectable_if (archinfo > 0) #Spill what I've uncovered.
            *set inform2 3
            *if doubt_hypothesis > 10
                *set doubt_hypothesis -10
                
            *else
                *set doubt_hypothesis 0
                
            *set covenstr +1
            
            @{(defiance > 3) You can only hope that the information you've gleaned on the Altruists won't be too damaging in Hypothesis's hands.|Expectations are expectations. Survival is survival. Regardless of your thoughts on the Altruists, if you don't prove yourself an asset, then Hypothesis might just write you off.} Besides, surely nothing you tell him holds the same significance as betraying the mission in the Zone. @{(archother = 1) Speaking of which, you omit Dion and Mal's conversation from earlier; whoever it is that 'doesn't want to be found' is more than likely connected to the Zone, and bringing it up could give you away.|}
            
            Hypothesis listens intently, hand darting rapidly across a notepad. His scratching pen sets your teeth on edge and nerves fraying, but you push through it and finish reporting. As you trail off his eyes flick to you and, assessing that you're done, he lowers the pen.
            
            "Satisfactory, Paradigm. Continue your work. Once I have his identity, outmanoeuvring Architect will be child's play."
            
            You nod, trying to ignore the churning guilt in your guts. 
            
            *label hypodiscusscg
            *if ((libra < 5) and (libra != 1))
                *label unrelatednote
                @{(inform2 = 6) "On the note of Control Group," Hypothesis continues. "She informed me|"On an unrelated note, I heard from Control Group} that you assisted her yesterday. It is good to know that you understand where your priorities lie."
                
                Another @{(inform2 = 5) nod. A little less jaunty this time.|shallow} nod.
                
                *goto hypopart3
            *elseif (libra = 5)
                *label trailingeyes
                @{(inform2 = 6) "On the note of Control Group," Hypothesis continues. "She informs|"On an unrelated note," Hypothesis continues. "Control Group informs} me that your group's interests clashed with our own yesterday." He pauses, eyes trailing you up and down. "However, by her account it was unavoidable, so given the delicate circumstances, I won't fault you for prioritising your cover. In future, I expect you to assist Control Group in the field."
                
                *if (punishjank)
                    Heart pounding, you manage another faint nod. @{intervene Twice in succession, $!{cg} has had your back.|$!{cg} had your back with this at least. Not so much when everyone was kicking the shit out of you.}
                        
                Heart pounding, you manage another faint nod. @{(inform2 = 6) $!{cg} had your back, but you didn't have hers. Awkward.|Thank fuck $!{cg} had your back.}
                
                *goto hypopart3
            *elseif (libra != 1)
                *goto thenoteof
                
            *else
                *goto hypopart3
    

*label hypopart3
*page_break
"There is one final matter." Hypothesis gestures to the case of vials, then plucks one from its berth, holding it aloft. @{introuble "Frankly, given your lapse in judgement, this is more than you deserve. Nevertheless, your task is too important for an inferior formula."|"Your task is of great importance to our goals. It would be remiss of me not to equip you as best I can."} He regards you, calm and cold as ice. @{introuble "I won't belabour the point, Paradigm. You know what is expected of you."|"Do not disappoint me, Paradigm."}

He extends his arm, offering his poison.

*if ((smashed) and (halpmecg = 1))
    *goto suddenpause

*elseif (vials = 1)
    *label suddenpause
    *set coveninfo +1
    *set heknew true
    
    As you reach for the vial, Hypothesis abruptly withdraws his hand, frowning. @{(expressive < 35) Involuntarily, you shrink back.|Though you want to shrink back, you keep the urge under control.} His inspection roves across you with the precision of a scalpel, dissecting you piece by piece. His expression is curious, then thoughtful.
    
    You want to vomit.
    
    "Tell me, Paradigm, when was your last dose of the formula?"
    
    *choice
        #@{punishjank I've already suffered the consequences. I'd be insane to lie.|I see no reason not to be honest.}
            *set theplan -1
            *if (punishjank)
                @{smashed You offer a silent plea to anyone who could be listening that Hypothesis doesn't ask about the broken vial.|Anything and everything could be another broken rule. Perhaps he'll find fault with your abstinence, but lie again, and he'll bring everyone back in here for another round.}
                
            *else
                You haven't defied any orders. @{smashed ...Broken vial notwithstanding.|Telling him should be harmless. }
            
            "Shortly after my first encounter with Wyrd and Architect," you answer.
            
            Hypothesis's eyebrows rise. You suppress a shudder. "Interesting." The notepad reappears, turned to a fresh page, no less. "That's an unusually long interval. Are you experiencing ill effects?"
            
            @{(expressive > 40) "Some cravings. They're manageable."|You shake your head.} Though, as usual, @{(expressive > 40) speaking of|sparing thought for} the @{(expressive > 40) hungering urges|cravings} summons them to the forefront of your mind.
            
            "Well then." He makes a note, and then another. "Do be careful not to stretch yourself too thin, Paradigm." He passes you the enhanced Juice. "That will be all."
                
        *if (ontome)
            *selectable_if (ontome = false) #I'm not stupid enough to lie when he already caught me out once.
                *bug you shouldn't be able to click this, since it only appears if 'ontome' 'is true.
            
        *else
            #@{punishjank Guess I'm insane.|} Lie.
                *set theplan +1
                *set defiance +1

                *if subterfuge < 50
                    *set doubt_hypothesis +5

                *if (punishjank)
                    Why don't you learn? Why do you push at the boundaries again and again? @{(terminate > 0) Do you have that much of a death wish?|You know better, and you fight him anyway.}

                *else
                    *if ((inform1 > 4) or (inform2 = 4))
                        This may not be smart. You've already played fast and loose with the truth here today. Lying again is really pushing your luck.

                    *else
                        This may not be smart. Probably isn't. 


                @{punishjank Because…|The} thing is, if the Coven has taught you anything, it's that knowledge is power. Knowing something about the Juice that Hypothesis does not is an ace up your sleeve.

                You aren't going to just hand it over.

                "I'm not sure. Two or three days ago, maybe."

                "Oh yes? Odd." Hypothesis regards you for an uncomfortably long time. Slice. Slice. Slice. Then, finally, he continues. "Well, use your best judgement on the next dose." He passes you the enhanced Juice. "That will be all." 
            
        #Give a vague answer.
            On the one hand, this information—knowing something about the Juice that Hypothesis doesn't—is potentially useful. On the other, you're not sure 'potentially' is worth the gamble.
            
            You come down somewhere in the middle.
            
            "Honestly, I don't remember," you say. "I don't think it's been all that long."
            
            "Hm." His eyes slice, slice, slice away. "I suppose it is my error, neglecting to advise you to keep track. Try to be more rigorous going forward, Paradigm. That will be all."
            
            You nod, and Hypothesis duly passes you the enhanced Juice.
 

*else
    You accept it.
    
    
The vial is warm in your hand as you approach the door.
    
Warm.

Pulsing.

*page_break


[i]Consciousness fades in, borne on a familiar voice.[/i]

[i]"Empirical, Categoric, please restrain the subject."[/i]

[i]Two sets of hands grasp your limbs. Your clouded eyes open, shadowy figures looming over you from all directions, backlit by a blinding overhead glare. Slowly, dimly, you grow aware that you're already tied down, bound to an operating table with straps securing your wrists and ankles.[/i]

[i]A face finally breaks through the shimmering fog as its owner leans closer. A man with glasses and greying hair, bright blue eyes gleaming with fervour. You've seen him before.[/i]

[i]He's holding a syringe.[/i]

*choice
    #[i]"Why are you doing this?"[/i]
        [i]The words crack, rasping.[/i]
        
        [i]"Any explanation would be lost on you, I'm afraid. Do hold still."[/i]
        
    #[i]"Please, don't..."[/i]
        [i]The words crack, rasping.[/i]
        
        [i]He ignores you. It's futile.[/i]
        
    #[i]"Fuck you, fuck you, fuck—"[/i]
        [i]A clammy, sweating hand claps over your mouth.[/i]
        
    #[i]There's nothing I can do.[/i]
        [i]You've long since lost any say in this conversation.[/i]
        
    #[i]Struggle in vain.[/i]
        [i]Buckles rattle as you twist and strain, the bindings pulling taut with barely an inch of give. The assistants intensify their grip, pressing you back down onto the table.[/i]
        
        [i]It's hopeless.[/i]
        
    
[i]The bespectacled man guides the syringe to your arm, then smoothly depresses the plunger, delivering the luminescent payload into your veins.[/i]

[i]Time holds its breath.[/i]

[i]The beating of your heart slows[/i]

[i]stops[/i]

[i]resumes[/i]

[i]And wildfire races through your bloodstream.[/i]

[i]Every nerve in your body rips and reforms, rips and reforms, rips and reforms, tearing, unmaking, reconnecting. You convulse violently, back arching with such ferocity it lifts your torso from the table, restraints rattling as you buck and twist and contort.[/i]

[i]Shouts from your captors. One demands you're held down. Another protests, panicked, that they can't. Someone is spitting curses, and you wonder if it is you, then realise it's impossible.[/i]

*page_break [i]You're busy screaming.[/i]
*if speciality = 1        
    
    [i]Something's inside you, scrabbling at the walls of your stomach. You choke and heave, a frothing black liquid bubbling from your mouth. As your convulsive retching intensifies, something long and sinuous crawls into your throat.[/i]
    
    [i]Your screams drown in another spurt of ichor. You can't breathe, the squirming snake blocking your air, suffocating you from the inside.[/i]  
    
    [i]Then the [b]thing[/b] begins wriggling up out of your stomach.[/i]
    
    [i][b]us. pain. eat. bite.[/b][/i]
    
    [i]a set of sensations and instincts not your own touch your mind.[/i]
    
    [i][b]prey. eat. us. pain.[/b][/i]
    
    [i]a spike of agony drills into your skull as consciousness seems to tear in two.[/i]
    
    [i]there's a writhing tendril slithering from your mouth, flailing for purchase, and just as you feel it slap against your cheek, so too is the sensation mirrored through an alien limb.[/i]
    
    [i]With one final heave, the thing slides from your throat, squeezing itself between your teeth, scrambling into the light. You feel it upon your chest, you feel yourself as its footing. The creature glistens, black and wet, reeking of meat, a flood of sensations chittering into your brain, anger-pain-fear-hunger-hunger-hunger-[/i]
    
    [i]hungerhungerhungerhungerhunger[/i]
    
    [i]The thing is moving, leaping, hunting. Someone shrieks, and you taste copper, a thrill of satisfaction coursing down your spine, teeth sinking deep into vulnerable flesh, to eat, and eat, and eat—[/i] 
    
    [i]Impact. Pain. You hit the wall with a wet smack. You…? hit—the—wall. You struggle to make sense of the input you're getting. You were punched? where did they…?[/i]
    
    [i]fingers, digging into your flesh. you wriggle and writhe, and screech.[/i]
    
    [i][b]bite. bite. bite![/b][/i]
    
    [i]Finally, your eyes refocus. One assistant wrestles with the thing from your guts, the other quivering on the floor, wailing, blood painting the tile. A hungry pang shivers through you. Then you're contorting in pain yet again as the assistant clasps the thing's undulating limbs and [b]pulls[/b]. It shrieks, broadcasting its agony to you as its tendrils stretch, strain, begin to tear from its body—[/i]
    
    [i]"Don't kill it!" barks the man in the glasses. "This requires study!"[/i]
    
    [b][i]us. eat. pain. bite. eat[/i][/b]
    
    *page_break [i]bite. eat.[/i]
    
*elseif speciality = 2
    [i]A hammer beats at your skull from the inside. Your mouth gapes as your screeches heighten, but then it yawns wider, and wider still, the bones and tendons of your lower jaw cracking and distending to breaking point and beyond rip. Your wailing reverberates, piercing and unearthly, longer and louder than your lungs should be able to muster.[/i]
    
    [i]Something crunches in your torso, a pop-pop-pop sounding as your ribs burst from place, chest unfolding like a flower. There should be blood, a distant thought manages to observe. Why is there no blood?[/i]
    
    [i]Instead, inky black ichor oozes over your body, coating flesh and bone. A bead of it forms at the end of a jutting rib, and you're possessed by the absurd urge to stop it from dripping into your open chest cavity, as if avoiding the ichor is more pressing than your body ripping itself apart. You start twisting to the side—[/i]
    
    [i]the black fluid is already inside. already fills you. instead of organs bared to the open air, there's a membranous layer stretched between the jaws of your splayed ribcage.[/i]
    
    [i]This should have killed you. Maybe it has, and your brain didn't catch up yet. Another convulsion wracks your body. Flesh tears wetly. Someone screams, and for once it isn't you. One of your captors flails around, hand impaled on a spur bursting from your left forearm.[/i]
    
    [i]Left.[/i]
    
    [i]but you turned to the right. How are you seeing—[/i]
    
    [i]blink, a pair of eyes.[/i]
    
    [i]blink, a pair of eyes.[/i]
    
    [i]You have two heads. [b]You have two heads.[/b][/i]
    
    [i]Neither mouth screams.[/i]
    
    [i]No. That comes from your chest.[/i]
    
    [i]thrash and convulse, break and reshape. cling to what shreds of 'you' remain.[/i]
    
    [i]hours, days, months later, comprehend words again.[/i]
    
    [i]"Goodness. I thought a moment I had another Project on my hands. Are you still with me in there?"[/i]
    
    *page_break [i]you don't know.[/i]
*else
    [i]It's as if your burning veins are trying to escape the fire, a writhing sensation rippling through muscle and flesh and bone.[/i] 
    
    [i]Then it starts to [b]push.[/b][/i]
    
    [i]Pressure intensifies as the thing inside your skin seeks a way out, your flesh stretching, distending, till surely it will give way, till surely you'll burst apart from the inside.[/i]
    
    [i]Instead, an ink dark membrane seems almost to bleed through your skin, spreading oily fingers across its canvas. The pain shifts, but does not fade, tiny needles prickling across every inch of you.[/i]
    
    [i]The membrane thickens, layering over and over upon itself, texture shifting to something more akin to plating as the weight of it mounts.[/i]
    
    [i]Bulkier, heavier, the shell grows and expands. Now it is your bindings straining, leather creaking with the effort of containing the new mass. You realise, faintly, that you can actually feel the straps digging into the chitinous armour. It's part of you.[/i] 
    
    [i]Snap. Snap. Snap. Snap.[/i]
    
    [i]You're out.[/i]
    
    [i]On a sudden feral instinct, you rocket up from the table and lunge at the assistant on your left, punching and clawing and tearing. A roar rips from you, mingling with the shout of alarm and pain as you drive an armoured fist into their face again and again and—[/i]
    
    [i]Something hits you in the back of the head. You topple to the side, unable to move.[/i]
    
    [i]"Impressive, very impressive. We shall certainly need to explore this expression of the formula."[/i]
    
    [i]And no amount of armour is enough to protect you from him.[/i]
    
    *page_break [i]now, or ever.[/i]
    
You don't quite remember when you reached the door, nor when you gripped the handle. Not with the Juice thrumming between your fingers.

Drinking this could put you back on that table, shredded from the inside out.

You're as helpless now as you ever were.

*choice
        #Get out of here.
            You step through the door and away from your memories.
            
            It's never quite that easy.
            
        #Get out of here with some scrap of dignity.
            *set instinctive %- 10
            You take a second to calm yourself, shake off the memories.
            
            They cling persistently. You have to settle for catching your breath.
            
            Then you step outside.
            
        #Get the fuck out of here.
            *set instinctive %+ 10
            You almost yank the door off its hinges in your haste to leave. Forget composure and dignity, you can't share a room with him for a single second more.
    

@{heknew As the door thuds shut, a thought arrives with the clarity of a lightning bolt.|The door thuds shut.}

@{heknew Hypothesis… knew you haven't dosed for a while.|}

@{heknew How?|}

*if (((trust_cg > 2) or (rel_cg > 60)) or (connectcg))
    *set cgmoment true
    @{heknew As you slump away, the question cycles around your head, spinning like a hamster on a wheel.|You slump away.} More than anything, you want to [i]leave[/i], be anywhere else than here, but you soon realise that until Hypothesis lifts the lockdown, you're confined to the base.
    
    Whoo.
    
    For now, the best you can do is to get as far from Hypothesis as possible. You shove the vial somewhere you can't feel, can't see, can't think about, and start shambling through the corridor. 
    
    Eventually, you emerge into what's dubiously classified as a 'staff room', a distinction it appears to have earned through the lofty qualifications of 'having sofas' and 'functional kettle'.
    
    You've spent perhaps ten minutes in here. Total.
    
    *page_break Look around.
    Empirical sits with Abstract, tall, dark, and blank alongside small and shifty. Solute prepares a drink, her movements characteristically dreamlike.
    
    $!{cg} perches in a corner, legs drawn up to her chest. She's the only one who spares you more than a passing glance. @{(punish > 1) Indeed, the others seem to go out of their way to avert their gazes. To fail Hypothesis is to be held in the Coven's contempt.|Not unusual; nobody's interested in putting themselves in Catalyst's sights.} Still, there's plenty of space. You can sit somewhere without imposing on anyone else. Preferable, actually.
    
    Your deliberations are interrupted. $!{cg} unfolds, quickly crossing the room.
    
    *if (punishjank)
        "Are you alright?" she murmurs. Her fingers thread together. She's struggling to look you in the eye.
        
        *if ((punish = 4) and (intervene = false))
            *choice
                #@{(expressive > 55) "I'm doing great, obviously."|"Fucking fabulous. Thanks for asking."}
                    *label fabulous
                    Her gaze drops to the floor. "Sorry," she whispers.
                    
                    What did she expect?
                    
                    *goto startstosaysomething
                #"You're seriously asking me that?"
                    Acid seeps into your voice. She participated as much as anyone not named Catalyst.
                    
                    *goto shrink
                #"I'll survive. Thanks for holding back."
                    *label wincecg
                    $!{cg} winces. "Don't… don't thank me for that."
                    
                    You tilt your head. @{intervene If anything's worthy of gratitude, it's her putting herself in the line of fire on your behalf.|She did more than she had to, whether or not she thinks it's worthy of gratitude.}
                    
                    *goto startstosaysomething
                #"What's a little kicking between friends?"
                    *label cavalier
                    *set expressive %+ 10
                    @{coven_history Your attempts to be cavalier would work better if your body wasn't still quivering.|You can't paste a fake smile to go with your false cheer.|You both know that it's little more than puffing out your chest.}
                
                    "Dime…" $!{cg} mumbles.
                    
                    Your barely-there bravado crumples.
                    
                    *goto startstosaysomething
                #Glare at her.
                    *label shrink
                    She shrinks in on herself. "Sorry. Shouldn't have asked."
                    
                    Yeah. Didn't stop her though, did it?
                    
                    *goto startstosaysomething
                
                #Just shake my head.
                    *label whispersorry
                    *set expressive %- 10
                    "Sorry," she whispers.
                    
                    You make a noise of acknowledgement.
                    *goto startstosaysomething
                    
            *label startstosaysomething
            She starts to say something else, but hesitates, glancing around at the room's other occupants, then back to you. "Got a minute?"
            
            *choice
                *if (punish = 4)
                    #@{intervene Hear her out. After all, she helped me.|I guess I'll hear her out. Even if she didn't stand up for me.}
                        *label hearherout
                        "Yeah?"
                        
                        @{coven_history Your eyes keep flicking to her hands, every slight movement causing you to reflexively flinch.|A numbing grey fog fills your head, a dull voice barely recognisable as your own repeating over and over again that disloyalty means punishment.|Your body and mind feel jagged, raw like an exposed nerve. One lapse may have cost you everything.}
        
                        $!{cg} fidgets. When she finally speaks again, each word is tentative. "If you want to rest, I can take you someplace." She falters, each hand tightly squeezing the opposite arm. "I'd, well, I'd appreciate the company, too. I don't want to be alone right now." She glances sidelong at Solute. Clearly, the others don't count.
                        
                        *label othersdontcount
                        *choice
                            #Accept. @{punishjank After the beating I took, resting up quietly sounds great.|A chance to decompress sounds good.}
                                "Sure. I don't mind." Your skull's been in a vice since you first walked in. You'd welcome any distraction.
                                
                                *label relievedsmile
                                *set rel_cg %+ 10
                                *set trust_cg +1
                                Her face cracks with relief. Beckoning, she moves past you and exits, leaving you to follow. 
                                
                                *label onyourback
                                You feel eyes on your back.
                                
                                *goto onthemovecg

                            #Accept. I want to bring something up with her.
                                "Alright." There's a few topics you couldn't discuss on the way, and the meeting created a couple more.
                                
                                *goto relievedsmile
                            *if (aro != 4) #One on one time with her? Where do I sign up? @{ftone [Flirt, passive]|}
                                *set interest_cg true
                                *set flirt_cg +1
                                *set rel_cg %+ 10
                                *set trust_cg +1
                                "Alright, because it's you," you say.
                                
                                She blinks and starts to frown, but it's battling against her mouth's attempts to quirk into a smile.
                                
                                In lieu of continuing that losing struggle, she quickly strides past you and exits, leaving you to follow.
                                
                                *goto onyourback
                            #Turn her down. I'm exhausted.
                                "I really just want to go home."
                                
                                *goto rightyeahcg

                            #Turn her down. I can't stand another minute in here.
                                This place is the stuff of your nightmares. Literally. You've no interest in voluntarily extending your stay.
                                
                                @{cg_dislike "No thanks. The second the doors open, I'm out."|"I need some space. Some air. Sorry."}
                                
                                *goto rightyeahcg
                            *selectable_if (not (talk_cg)) #"What makes you think I'll have changed my mind?"
                                She made a similar offer at the library, after all.
                                
                                Her mouth pulls into a wry smile. "I'm an optimist," she says, bone dry.
                                
                                *goto othersdontcount

                    #@{intervene Can't she leave me alone? I'm sick of Coven.|I don't want to be around her after what she did back there.}
                        *label leavemealone
                        *set rel_cg %-7
                        
                        "$!{cg}, if it's not about the mission, I don't want to hear it," you say. So what if it's blunt? Your manners must have been knocked out of you.
                        
                        "Right, of course," $!{cg} mutters. "It's—yeah. Nothing important. I'll leave you @{scrapcat be. Just, watch out for Catalyst, alright? I don't know what you did to piss him off, but he's been lurking around the place."|be."}
                        
                        @{scrapcat With that, she slinks back to her corner, head down.|She slinks off to her corner, head down.}
                        
                        *if (scrapcat)
                            *goto lurkingaround
                        
                        *else
                            *goto finnicky

                *else
                    #I guess I'll hear her out.
                        *goto hearherout
                    #Can't she leave me alone? I'm sick of Coven.
                        *goto leavemealone

                #I'm a beaten, shivering mess. I don't have another conversation in me.
                    "$!{cg}…" you mumble. "I just want to go home."
                    
                    *label rightyeahcg
                    "I—right, yeah, of course." She conjures a smile so tired it's already decaying. @{scrapcat "In that case, just, watch out for Catalyst, alright? He's been lurking around the place, and I know what that look means.|"Maybe some other—well, it's not important. Take care of yourself, Dime. Get some rest."} 
                    
                    She heads back to her corner.
                    
                    *if (scrapcat)
                        *goto lurkingaround
                    
                                    
        *elseif (punish = 4)
            
            *choice
                #@{(expressive > 55) "I'm doing great, obviously."|"Fucking fabulous. Thanks for asking."}
                    *goto fabulous
                #"I'll survive. Thanks for standing up for me."
                    *goto wincecg
                #"Barely felt it. Maybe Catalyst's going soft."
                    *goto cavalier
                #Glare at her.
                    *goto shrink
                #Just shake my head.
                    *goto whispersorry
                
            
    *else
        "Hey, Dime," she says. "Was hoping you'd come this way. Do you…" She hesitates, and as she resumes, each word is tentative. "Could you, keep me company for a bit? I know it's been a long day, I just, don't want to be alone right now." She glances sidelong at Solute. Clearly, the others don't count.
            
        *goto othersdontcount
    
    

*else
    @{heknew Your whirling thoughts screech to a halt as you catch sight of someone waiting outside. $!{cg}.|$!{cg} is waiting for you.}
    
    She's leaning on the wall, and her head turns to you the moment you exit.

    Silence stretches, her shadowed eyes lingering on you.
    
    *if (scrapcat)
        At last, she speaks. "Catalyst was lurking around. Don't know what you did to piss him off, but be careful."
        
        And she turns and walks away.
        
        *label lurkingaround
        *choice
            #Oh gee, what valuable advice.
                'Be careful of Catalyst'? What a concept. What would you do without $!{cg} to look out for you?
                
                *if ((punishjank) and (intervene = false))
                    Ignore the part where she clearly didn't. 
                    
                Too bad she's out of range for a sarcastic retort.
                
                *goto finnicky
            #@{punishjank He still isn't satisfied?|Should have seen that coming.}
                *set imfinnicky true
                @{punishjank You shudder, body throbbing with its fresh bruises. There's no surge of fear. That would imply the fear ever left.|Catalyst isn't one to forgive a slight. If you don't want him to exact revenge tenfold, you'll need to keep your head on a swivel. Even then, you could be backed into a corner.}
                
                @{punishjank Catalyst will exact his toll as many times as he feels like.|}
                
                For now, there's nothing you can do about it.
                
                *goto finnicky
            #I'll take the warning in the spirit it was meant.
                *set rel_cg %+ 10
                She's looking out for you, Kind of. 
                
                *if ((punishjank) and (intervene = false))
                    Maybe it's some kind of recompense for not protecting you.
                
                "Thanks," you tell $!{cg}'s back. She halts mid-stride, hesitates, and then continues.
                
                Okay then. Good talk.
                
                *goto finnicky
            #Whatever.
                *set imfinnicky true
                Today's put you at about five times over maximum capacity. There's not an ounce of brainpower remaining for either $!{cg} or Catalyst.
                
                *goto finnicky

    *else
        *set imfinnicky false
        Her mouth opens.

        Then it shuts.

        With a curt nod, she turns and walks away.
        *choice
            #O...kay?
                Sometimes, you think you're close to understanding $!{cg}. This is not one of those times.

            #Oh sure, that wasn't weird at all.
                Why bother waiting if she's just going to dip the moment you show up?

            #At this stage, I literally do not care.
                *set imfinnicky true
                Today's put you at about five times over maximum capacity. There's not an ounce of brainpower remaining to contemplate $!{cg}.
                
            *selectable_if ((punishjank) and (intervene = false)) #Maybe she's guilty.
                She did nothing to protect you. Could be a pang of conscience in there somewhere. @{cg_dislike Probably not.|Who knows?}
                
        *label finnicky
        @{imfinnicky Blessedly, the next thing you hear is|Doesn't matter. With} Gremlink's voice piping through the PA system to announce the lockdown is @{imfinnicky lifted. You|lifted,} you can finally leave.
        
        *if (cgmoment)
            Vacating the staff room as swiftly as you entered it, you slump off through the corridors of the base.
            
        *else
            You slump your way through the base, shoving the vial somewhere you can't feel, can't see, can't think about. You're @{punishjank battered and halfway to broken,|exhausted to the bone,} and you want to go home.
        
        *label shambleshambleleave
        Shambling like the walking dead, you finally reach an exit. The past has haunted you all day. Maybe you're a ghost too.

        Two blocks along the way, your pocket buzzes with a text. Dion.

        [i]We have a lead. Let's discuss tomorrow.[/i]

        No rest for the villainous.
        *goto endofcurrent

*label onthemovecg
*set talk_cg_hq true
The route $!{cg} takes is familiar, and sure enough, you soon find yourself at the room that hosted much of your training. $!{cg} shoves her way inside without slowing, and you scamper after her before the doors can close on you.

As best you can tell, your former dojo is untouched since your last visit. The crash mats are rolled up and stacked in a neat row against one wall, and the various articles of furniture serving as obstacles are shoved to the opposite side. You've lost count of the times you've been tossed to the floor in here. It's almost nostalgic.

For $!{cg}'s part, she doesn't spare a glance for your environment, crossing the room with purpose and yanking open another door. She waves you on, and you move past her into a small annex.

Alright. This is new.

$!{cg} very carefully shuts the door. A dingy, naked lightbulb illuminates your surroundings, though there's little to look at, just a sleeping bag on the floor and a metal cabinet missing both doors. The air carries faint aromas of cleaning products and rust. Small wonder it's your first time in here, it's practically a cupboard.

"We've got privacy here, if you keep your voice down," $!{cg} murmurs. "There's nowhere for Gremlink to bug."

*choice
    #Look at her silently.
        *set expressive %- 10
        "Just… thought I'd mention it," she adds, glancing away.
        
    #"How can you be so sure?"
        You don't think Gremlink knows what Gremlink can do half the time.

        "The cameras are all pre-bought, and there aren't any hiding spots. Also, the earbuds don't get a signal. Some kind of interference."

        @{(expressive > 55) "Oh good, there's lead in the walls."|"How convenient."}

        @{(expressive > 55) She almost laughs.|She shrugs. "Privacy, not security."}

        @{(expressive > 55) |Hm. Fair enough.}

    #"Is this where you sleep?"
        $!{cg} looks self-conscious. "Occasionally."

        *if (sleepask)
            "How occasionally?" you press, recalling her evasiveness on the subject.

            She squints at you, unimpressed. "Occasionally enough."

            Yeah, that's what you thought.

        *else
            @{(expressive > 55) "It's almost as nice as my digs."|Rarely does your own abode compare favourably to another.}

            @{(expressive > 55) She doesn't-quite laugh. "Sorry."|She nudges the sleeping bag with a foot, going quiet.}

            @{(expressive > 55) You shrug. It was your joke.|}
                    
     
    #Shrug. Fair enough.
        Your lack of comment passes with a lack of comment, which passes with a lack of comment—
        
    *selectable_if (intervene) #I should make sure she's okay. She stood up for me.
        "Are you alright?" you ask.
        
        She tries a smile on for size. It's weak, wavering. "I can take it." Before you can reply, she keeps going. "I'd rather we don't—can we talk about something else?" 
        
        "Okay, but… thanks."
        
        She looks at the floor.
        

$!{cg} seems unsure of herself. Self-conscious. @{(observation < 25) Even you can tell.|}

You'd say that she has an interesting idea of what 'keeping each other company' means, but you're hardly any better.

It's never more stark that you're only mimicking the steps of socialising in the Altruists' company than when you're with her. Without the guide rope of an objective, you're both as hopeless as each other.

…But it beats being hopeless alone.

*label cgmenu
@{(cgtalk = 3) You put your back against the wall and slide all the way to the floor. $!{cg} The silence is oddly comfortable. At least you can hear yourself think, have time to mull over potential topics. (alternatively, time to wade through the aforementioned hopelessness). Though, after the saga today has been, you don't think either of you have the energy for a lengthy conversation. Best you prioritise. Top two, maybe?|Exhaustion pours from both of you in waves. You've got one more topic in you, if that.}
*choice    
    #@{talk_cg I could go for another normal chat, like at the library.|I'm regretting turning down her offer of a talk at the library. Let's fix that.}
        *set cgtalk - 1
        *set rel_cg %+ 10
        
        @{(expressive > 60) "Stop me if you've heard this one before," you begin. "Want to just talk for a bit?"|"Feel like talking about nothing for a bit?"}
        
        @{talk_cg A smile breaks through her fatigue like the dawning sun.|A tentative smile creeps onto her face.} "You mean that?"
        
        "Of course."
        
        Despite good intentions from both of you, conversation is slow to start. @{talk_cg Even the ice coming pre-broken can't entirely compensate for your collective social struggles.|Neither of you know quite what you're doing here, and interactions with one another as people instead of catspaws have been few and far between.}
        
        Still, you get there. Gradually. @{talk_cg A single candid chat barely begins to fill the gaps, leaving plenty of ground for you to cover.|In a way, the size of the gaps makes things easier.} If your acquaintanceship was normal, you'd have long since discussed all the mundane topics, from hometowns and previous jobs to preferred weathers and the kind of places you'd go for fun. It hangs heavy and unspoken how much of the conversation is past tense. Regular experiences stopped for both of you when you set foot in the Coven.
        
        Conspicuously absent from your talk is family. $!{cg} doesn't ask and doesn't volunteer information, and you follow suit. You wonder how yours compares to hers. Stiff competition.
        
        Instead, @{cgfood she tells you that she's been sketching lately, watching carefully for your reaction as she brings it up. |you learn that her favourite food is carbonara, though she spares no mercy for Alderbrook's restaurants and their supposed habit of butchering the dish.}
        
        @{cgfood "I'm really bad," she says. "Just kills time between all the other stuff."|"I don't even bother any more," she says with a scowl. "I barely ever get to eat out and I'm not wasting that on disappointment. I just order a rack of ribs instead. Those are impossible to fuck up."} 
        
        @{cgfood "It doesn't have to be good," you tell her. "And everyone's bad when they start."|"I don't know, I've known some terrible cooks."}
        
        $!{cg} @{cgfood smiles.|shudders.}
        *set cgfood true
        
        Eventually, things come to what feels like a natural conclusion. You don't want to force it, and allow the silence to breathe.
        
        *gosub talkingwithcg

    #Ask her what she made of Hypothesis's breakthrough.
        *set aboutwork +1
        *set cgtalk -1
        
        "This enhanced formula," you venture. @{(expressive > 55) "What's your take?"|"Thoughts?"}
        
        *if (cgtell)
            $!{cg} lays a hand across her face, letting out a shaky breath. "Honestly, I'm scared," she admits. "You and I both know what the Juice does. The thought it could get worse is…" She trails off, shaking her head. Her other hand circles her forearm, squeezing. "I don't even know how Hypothesis's power works, or what 'improvement' he could have made."   
            
        *else
            $!{cg}'s quiet for a while. Her hand circles her forearm, squeezing. "It's interesting. I had no idea Hypothesis was iterating on the Juice. I'm not sure what he could have done to improve it, but then, I don't know how his power works."
            
        Now that surprises you; you've always assumed that Hypothesis's power is just something you're too low on the totem pole to be told. "Wait, you don't?"
        
        She shakes her head. "Best I can tell, nobody does. Not that I'm going around asking everyone, but I've looked into it."
        
        "Huh."
        
        "Yeah." $!{cg} stares at her own grasping hand. Eventually, she looks back up. "Assume you've got an opinion too, since you brought it up. The enhancement, that is."  
   
        *choice
            #I tell her it's a bad thing.
                *set trust_cg +1
                "I don't see how anything good comes out of amping up the Juice," you say. "The effects are already strong, @{(knowledge > 45) and I doubt the new version has been rigorously tested. Hypothesis would have brought out his guinea pig."|and missing doses is bad news. That only gets worse, right?"}
                
                *if knowledge > 45
                    $!{cg} laughs. It's a small noise, escaping rather than freely given. "Sometimes I forget you're a nerd, Dime."
                    
                    "Hey."
                    
                    "Sorry. You're absolutely right," she adds. @{cgtell "Either he's completely confident, or he doesn't care about collateral to the Coven."|"It's unusual for him. I guess he must be satisfied with whatever he's done."}
                    
                    @{cgtell Well, even if the former is true, so is the latter.|And that's sure no guarantee of safety for you and her.}
                    
                *else
                    $!{cg} nods. "Exactly. Good to know we're on the same page." @{cgtell She gives you a significant look. More powerful Juice sure won't benefit that plan of hers.|Her expression clouds, though she keeps whatever is on her mind to herself.}
                    
                    
                The conversation lapses there. Seems there's nothing else either of you have to say about the Juice.
                    
            #I tell her it's a good thing.
                *set trust_cg -1
                "You never know, it could be beneficial," you say. "Stronger powers have to be worth something." 
                
                @{cgtell $!{cg} looks at you, expression blank. "Not if they cost everything."|$!{cg} makes a face. "Maybe. You could be right."}
                
                @{cgtell With that, she clams up, done with the subject.|That appears to be all she has to say on the subject.}
                
            #I need more information first.
                "Too soon to say," you tell her.
                
                "Fair enough." @{(observation < 25) Is she disappointed? You wish you were better at reading expressions.|While she seems disappointed, she doesn't attempt to force an opinion out of you.}
                
                Thanks to your non-answer, the subject of Juice kind of just dies.
                
        *gosub talkingwithcg 
    #@{aboutadventure_cg I'll go ahead and explain that Beth is Phalanx. In for a penny.|I want to talk about Beth.}
        *set aboutbeth_cg 2
        *set cgtalk -1
        
        Her presence is an anchor, dragging you into the depths. You need to get this off your chest, alleviate the crushing pressure of all too many secrets.
        
        *if (aboutadventure_cg)
            "So… Phalanx."
            
            "Yeah?"
            
            You swallow. "You probably figured this out, but… yeah. She was part of that group. She ignited. Got away."
            
        *else
            Building up the nerve is neither quick nor easy. You dredge your thoughts together over the course of several minutes, sitting in silence while $!{cg}—well, honestly you're so in your head she could be doing anything.

            Finally, you speak. "$!{cg}."

            "Yeah?"

            "Phalanx."

            That gets her attention. "What about her?"

            "She was with me. When it." You swallow. "Happened. She ignited. Got away."
        
        *if (dated_beth)
            *choice
                #That's everything.
                    *set aboutbeth_cg 3
                    Not even you know where you stand with Beth, and you can't see how spilling your relationship history would help with that.
                    
                    *goto jesusdime
                #Tell her we were an item.
                    *set aboutbeth_cg 4
                    "She uh, um." You tap your knuckles together, then force it out. "She's also my ex."
                    
                    In the moment before you find great interest in the backs of your hands, $!{cg}'s eyes go wider than you've ever seen. "You're fucking with me."
                    
                    "No," you tell your fascinating hands.
                    
                    "As in, you broke up with her before all that, or…?"
                    
                    Wow, these hands sure are something. "We were together at the time."
                    
                    "That's—jesus. That's fucking brutal."
                    
                    @{(expressive > 45) Yup, pretty much.|A fair assessment.}
                    
                    *goto maybecatharsis
        *else
            @{(pastcrush = 1) You're not going to humiliate yourself mentioning your crush on her. That secret can stay buried.|And there it is. You've spoken it aloud.} 
            
            *label jesusdime
            @{aboutadventure_cg "I thought maybe that was it," $!{cg} murmurs. "I didn't want to ask."|"Jesus, Dime."}
            
            *label maybecatharsis
            @{aboutadventure_cg You already told her about your past, so really this is just providing the last few puzzle pieces.|Confirming Beth's identity permanently breaks the seal between 'then' and 'now'. For better or worse, you've linked the story together.} 
            
            @{aboutadventure_cg That's how it should be. But it's not. Call it compartmentalising, but you could at least pretend that 'then' and 'now' were different. Confirming Beth's identity breaks that seal permanently.|} Hopefully, this isn't a mistake.
            
            There's everything to say and zero desire to say any of it. $!{cg} gives you some welcome space and welcome silence.
            
            *gosub talkingwithcg
    #@{(aboutbeth_cg > 1) I already talked about Beth. Guess it's 'digging up $!{forename}'s past' hours.|Without quite knowing how it started, I'm suddenly talking about that night.}
        *set aboutadventure_cg true
        *set cgtalk - 1
        The story slips from you seemingly of its own volition. The five of you. Your urban exploration hobby slash career. Finding the compound. Encountering the Project. Beth, Grant, Shauna, and Prii. @{(expressive > 45) Your voice strains and wavers, taut with emotion.|You stop and start, numbness seeping from you and into your voice.} With clouded eyes, you stare at nothing.
        
        $!{cg} listens, quiet and attentive all the way to the finish. To the point your history becomes shared.
        
        "I'm so sorry," she whispers. "None of you deserved that."
        
        You make a sound. @{(aboutbeth_cg >1) Speaking about Beth's part in it all did not come close to preparing you for the entire thing.|It takes everything you've got.}
        
        "I don't know what to say." Her breath catches. You hear her shift around. "I—do you want a hug?"
        
        *choice
            #Yeah.
                You incline your head in a fraction Dion would be proud of.
                
                $!{cg} puts her arms around you, awkward and stiff.
                
                "I'm kind of out of practice," she mumbles.
                
                It doesn't matter. A stilted hug is still more than you've ever had to soothe that night.
                
                *choice
                    #Silently cry.
                        The tears spill down your cheeks without a sob or a gasp.
                        
                        It still hurts. It hurts beyond reckoning.
                        
                        Just… sharing it with someone, and being comforted.
                        
                        That's something.
                        
                        *label breakapart
                        Eventually, you break apart. She's let the silence stand all the while, and you're glad of it. Words would only have brought complications.
                        
                        *goto cgreflect
                    #Remain in her arms a while.
                        The awkwardness ebbs as you settle.
                        
                        @{touchingokay Touch isn't usually a comfort for you, but here's a rare exception.|It's odd getting a hug from her. Odder still that you can find comfort in it.}
                        
                        Your past is far more than few moments of sympathy can wipe away.
                        
                        But… it has to start somewhere.
                        
                        *goto breakapart
                    #Disentangle myself.
                        You slip out of $!{cg}'s arms without resistance, giving another tiny nod to let her know she hasn't done anything wrong.
                        
                        You're just… fragile. Emotionally overtuned. A brief hug is the limit of your tolerance. It helped. You think. Maybe.
                        
                        She respects your space, shuffling just slightly further away.
                        
                        *goto cgreflect
 
            #No.
                *label smallestdegree
                Your head moves by the smallest degree possible to be considered a shake.
                
                "Alright." She shuffles, giving you just a little more space.
                
                *label cgreflect
                $!{cg}, you reflect, is the only person you could tell the story in full. Anyone else, there'd be a lie or an omission for the sake of secrecy.
                
                Does it hold true in reverse? Do you want it to?
                
                Either way, that's as much of that night as you can handle in one conversation.
                
                *gosub talkingwithcg
            #I do, but not from her.
                $!{cg} was [i]there[/i]. Part of it.
                
                She can't comfort you.
                
                *goto smallestdegree
        
    #Ask what @{(libra = 1) intel she was trying to get yesterday.|what the deal was with her Businessman contact.}
        *set aboutwork +1
        *set covenbusinessintel true
        *set coveninfo +1
        *set cgtalk -1
        
        You probably won't get another opportunity to ask, and $!{cg} getting assigned to the field is one of the few hints you have at the overall agenda.
        
        *if libra = 1
            "Hey, you know that guy you were working with?" @{guiltkill [i]The one I killed,[/i] you add silently.|you say.} "What was going on there?"
            
            She blinks. "Wasn't even thinking about that. Poor @{(watson = 2) Watson. He's going to have a real bad time." She grimaces and shakes her head.|Watson." There's no particular judgement in her voice.} "Anyway, he was giving me an inside line on the Businessmen. Couldn't really use Variable for that; too likely that it'd compromise them. So yeah, reliable source of information. It's a shame."
            
        *else
            "So what was going on with the dead drop yesterday?" you ask.
            
            *if (fissionmailed)
                She blinks. "Surprised you'd want to know," she says. "Dunno about you, but after the day we've had, I almost forgot about that."
                
                You shrug. "I've been wondering."
                
                *label anodcg
                @{fissionmailed A nod.|The smile stays.} "I needed intel on the Businessmen to keep doing my Libra thing. It's hard staying ahead of their entire operation alone, and I can't use Variable or we're risking compromising them. @{fissionmailed As for the specifics, there's quite a bit about their day to day in there. They've got some surprising connections."|The goal was to find more about their day to day and any connections they've got, but, well, you know. Didn't get the info in the end."} 
                
            *else
                "The intel you stopped me getting, you mean?" Her mouth twitches wryly, teasing. @{librafail Looks like she's cooled off about what happened.|}
                
                "Uh, yeah, that."
                
                *goto anodcg
                

        "It was all just for the crimefighting, then?" You're a little disappointed; that's hardly the revelation you hoped for.
        
        "Mm, no, not exactly," $!{cg} replies. "I'm pretty sure Hypothesis has Variable in there as either a warning system or a contingency plan for if the Businessmen start encroaching on us, so it's difficult for them to sneak information out of the loop. Only a little of my assignment is about being a pain in their collective suited ass. The rest—least as far as the Businessmen are concerned—is completely verifying they've got no connection to the Zone incident."
        
        The Zone? Again?
        
        You must have shown some kind of reaction, because $!{cg} nods. "Yeah. Interesting, isn't it?" She goes quiet, gaze lifting to the ceiling. She scans it slowly, giving the same thorough treatment of the room's four walls. Finally, she looks back to you, dropping into a whisper, leaning in close. "Someone went missing in all that. Someone Hypothesis wanted. There's a possibility the Businessmen were responsible." $!{cg} straightens up again, steady eye contact instructing you to move on from this. "The incident had a ton of moving parts, so you know, worth checking on," she continues at normal volume.
        
        Not the first you're hearing of missing people. @{(archother = 1) Dion and Mal were talking about finding someone too.|}
        
        "I see," you say, inclining your head to her, matching her signal. No more on the subject. Not here. 
        
        *gosub talkingwithcg
        
    #Get her advice on my objectives.
        *set aboutwork +1
        *set rel_cg %- 10
        *set instinctive %- 10
        *set cg_insight true
        *set cgtalk - 1
        
        It's awkward to discuss your 'job' right now, but @{punishjank with Hypothesis's ultimatum fresh in your mind, you can't pass up the opportunity to pick $!{cg}'s brain.|you any way you slice it, you need to keep Hypothesis sweet, and $!{cg}'s the only helping hand you've got.}
        
        "Sorry to bring up work, but I could use some advice on figuring out Architect and Wyrd."
        
        "Yeah? Hm." While her business face quickly asserts itself, you don't miss the flicker of resignation it replaces. "If I were in your shoes, I'd look between the lines with those two. They aren't allies of convenience, there's some kind of existing connection between them. So, search for the gaps; consider the kinds of things they don't seem to need to talk about; look for allusions and unspoken agreements." She rests an elbow on her knee, and her chin on her fist. "If they ever disagree with each other, pay close attention. Assess the type and scale of the disagreement, and examine the hierarchy of it. Does Wyrd just do exactly what Architect says? Do they protest? Is it begrudging? Does that change with the circumstances?"
        
        Slowly, you nod. They've certainly argued a few times. "What comes next, though? How do I turn an assessment into something concrete?" 'They don't always agree' isn't exactly the cutting edge of espionage.
        
        "Dig into the hierarchy. Compare it with what else you know about them, and what they've told you. Hunt down any inconsistencies until the lead's exhausted. If it's inconsistent, there's a lie somewhere, and the things that someone chooses to lie about can tell you a lot." $!{cg} shrugs tiredly. "Wish I could give you a foolproof guide, but that's not how this works."
        
        "It's @{cg_dislike whatever.|fine.} Thanks for the help,"
        
        "Mm."
        
        Looks like she's done. Still, she's given you plenty to chew on.
        
        *goto talkingwithcg
        
        
*label talkingwithcg

*if cgtalk > 1
    *goto cgmenu

*else
    *goto concludecg


*label concludecg
*if aboutwork = 0
    *set trust_cg +2
    *set connectcg true
    
*elseif aboutwork = 1
    *set trust_cg +1

*page_break
You catch your head nodding. $!{cg}'s not looking much better, eyelids a flutter. @{interest_cg Something of yours flutters too.|}

She starts to speak, but the words are swallowed by a yawn. She looks bashful, then tries again. You're expecting her to bid you goodnight.

You expect incorrectly.

@{(cg_firstnamebasis = 2) "Before. You asked me my name." |"This might be kind of a dumb thought but… whatever."} Her eyes dart to yours, then away, then back. "You're the closest thing I've got to a friend, and I assume you don't totally hate my guts, since you're here and all, so…" She takes a deep breath. "I don't mind if you'd rather not but… @{(cg_firstnamebasis =2) tell you mine if you tell me yours?"|want to trade names?"}

It's a surprise to realise that her suddenly vulnerable expression is no longer unfamiliar.
*if (pseudonym = false)
    *choice
        #About that...
            *set rel_cg %+ 10
            *set trust_cg +1
            *set cgmc forename
            "Well, you actually already know mine." @{(expressive > 55) You're trying not to smile. Hey, it's kind of funny, you know?|This is awkward.}
            
            For a moment, confusion replaces vulnerability. "No I don't."
            
            "Think about it a sec."
            
            "Wait…" Her eyes narrow as the wheels turn, then she groans in exasperation. "You've gotta be kidding. You seriously used your real name as a pseudonym?"
            
            You shrug lopsidedly. "I don't exactly have a regular secret identity to worry about."
            
            "I guess I'll give it to you. On a technicality."
            
            "Very gracious. Your turn."
            
            All of a sudden, she's looking very sheepish. "Uh… it's Mirella," she mutters.
            
            @{(expressive > 55) There's no stopping the smirk this go round.|Hold on a damn minute.} "So you did the exact same thing?"
            
            "Bite me, $!{aka2}! I got introductions sprung on me, what's your excuse?"
            
            "I mean, it's not like anyone would have—" You stop, because that turned out to be wrong, didn't it?
            
            With genuine grace this time, $!{cg} lets it pass.
            
            *goto afternames
        #She already knows it, but I don't want to say.
            *label nothankscgname
            Telling her feels like one step too far, one step too familiar.
            
            "Sorry…"
            
            A tiny little sigh. "No, don't worry. @{(cg_firstnamebasis = 2) It was a dumb thought anyway."|I did say it was a dumb thought so, yeah."}
            
            Refusing the offer doesn't so much sour the conversation as draw all the remaining energy from you both. When Gremlink's voice—a little muffled in this room—chirps up over the PA that the lockdown is lifted, you get up to leave.  
            
            "See you, Dime." @{scrapcat She pauses, considers, speaks. "Look out for Catalyst. I don't know what you did, but he was lurking around before and I think it's you he was after."|}
            
            @{scrapcat Fuck. You nod. "Thanks for the warning. Bye, |"Bye,} $!{cg}."
            *page_break
            *goto shambleshambleleave
            
            
*else
    *choice
        #I want to.
            *set rel_cg %+ 10
            *set trust_cg +1
            *set cgmc forename
            
            The more you think on it, the more certain you get that you want to share this connection with her, this tiny piece of humanity amidst the monsters.
            
            "I'm $!{forename}," you whisper. @{nickname "My friends would mostly call me $!{mc_name}."|}
            
            "$!{forename}," $!{cg} repeats, gentle as if her voice was cradling a baby bird.
            
            A wave of inexplicable, indescribable emotion washes over you. Hearing your name from Beth was one thing, but from $!{cg}? For the first time ever?
            
            Tears prickle at your eyes, and you dash them away before you make a mess of yourself.
            
            "I'm Mirella," $!{cg} says.
            
            That snaps you out of it. "Mirella? But didn't you…?"
            
            *label yeahh
            She sighs. "Yeahh." She fidgets under your sceptical eye. "Hey, introductions got sprung on me, okay?"
            
            Suddenly you're @{yeahhh smirking.|not sniffling, you're smirking.} She flips you off.
            
            *goto afternames
        #I'd... rather not.
            *goto nothankscgname
        *selectable_if (pseudopinion = 3) #I bring up that $!{aka2} is feeling more like me.
            *set yeahhh true
            *set cgmc aka2
            The thought hasn't gone away since it appeared back at the Hounds' building. 

            It's hard to articulate, and you're stumbling over the words. "$!{aka2} wasn't my name before, but I'm kind of, getting attached to it, I guess? I got to pick it for myself. It matters."

            "Huh." $!{cg} frowns in thought. "I suppose I can understand, but…" She shakes her head. "Doesn't matter. Not about what I think."

            "I know that technically isn't holding up my end of things—" you begin, but she interrupts.

            "Still counts. I'm Mirella."

            Your wheels turn. "Wait, but didn't you…?"

            *goto yeahh
        

*label afternames
*set cgdisplay 4
*page_break
You regard one another, neither quite sure what to say. Five years to finally exchange names. There's no guidance for it.

*if instinctive >55
    Well, someone's got to leap into the unknown. "Good to meet you, Mirella."
    
    She smiles. "You too, $!{cgmc}."
    
*else
    She leaps into the unknown first. "Well… good to meet you, $!{cgmc}."

    "Same to you, Mirella," you reply. She smiles.

*if ((flirt_cg > 2) and (rel_cg > 65))
    Sitting here in this tiny room, side by side, shoulders almost touching, it feels like you could be the only two people in the world.
    
    Mirella's eyes are on you, the usual intensity giving way to something softer. There's a question in her gaze, if you care to answer.
    
    @{t_cg How are you letting her do this to you? She's a pain in the ass.|}
    
    *if (romance_wil > 2)
        *if (poly_wilk)
            You hesitate, thinking of Wil. $!{whe} told you ${whe} doesn't mind if things are open between the two of you, but this feels different. You haven't discussed with ${whim} ahead of time, and ${whe} doesn't even know Mirella.
            
            Though if you're going to bring secrets into the equation, you're already lying to Wil several times over.
            
        *else 
            Wil's face swims to the forefront of your mind. @{(romance_wil = 4) You're dating. Even if you haven't exactly had many romantic evenings together, there's still a commitment.|You may not be dating, per se, but there's certainly something between the two of you.}
            
            @{(hookup_wyrd > 1) $!{whe} wasn't bothered about you taking Mal up on their invitation, but that was with ${whis} full knowledge and consent. This feels different.|Do you really want to follow this feeling and discard another piece of your integrity? Add yet another lie to the pile?}
            
            *choice
                #What Wil doesn't know won't hurt ${whim}. Lean in closer. @{(brokenheart <5) |[Start Romance]}
                    @{poly_wilk And with those lies in mind...|That's just it. You're already misleading Wil.} Why baulk here? @{(romance_wil != 4) Technically, you're not even together.|}
                    
                    *if brokenheart < 5
                        *goto brokenheartlean
                    
                    *else
                        *goto mirellakiss
                        
                #I can't do this to Wil.
                    *set hesitate_cg 3
                    Going behind ${whis} back like this feels wrong, even @{(romance_wil = 4) cruel. $!{whe} asked to wait.|without you both formally together.}
                    
                    Guilt worms into your gut. It'd be betrayal upon deception.
                    
                    You turn your head from Mirella and another bad decision.
                    
                    *goto i_anyway
                    
                #It wouldn't be fair to Mirella. I should tell her.
                    *set mention_wil_cg true
                    "Before we…" You're not sure where that sentence goes, and do not conclude it. "I need to tell you something."
                    
                    Mirella withdraws, not just physically, but walls springing up about her in an instant. "Yeah?" she says, guarded.
                    
                    @{(romance_wil = 4) "I'm kind of, seeing one of my teammates."|"I've got kind of a complicated situation going on with one of my teammates."}
                    
                    She studies you. For once, you do not feel as if she's laying you bare. It's just… thoughtful.
                    
                    Then she smiles. "How am I not surprised you managed to get involved with your mark?" She shakes her head. "Setting aside that I don't think you're being especially smart, I don't care. Here and now? It's you and me." She swallows hard. "Us."
                    
                    *choice
                        #In that case... I lean in closer. @{(brokenheart <5) |[Start Romance]}
                            *if brokenheart < 5
                                *goto brokenheartlean
                            
                            *else
                                *goto mirellakiss
                        #I still can't.
                            *set hesitate_cg 4
                            Your emotions are too damn messy to figure out and you're too damn tired to handle getting pulled in two different directions.
                            
                            @{(brokenheart < 5) $!{prev_li}'s face flashes into your head. Three.|} You're a disaster area.
                            
                            "I… sorry. This is—"
                            
                            "$!{cgmc}," Mirella stops you. Her expression is surprisingly gentle. "Let's leave this alone. Nothing happened. It's fine."
                            
                            You nod, staring into your lap, no closer to sorting through anything rushing around your head.
                            
                            *goto awkwardminutes
                            
                
        
    *else    
        *choice
            *if (brokenheart < 5)
                #Lean in closer.
                    *label brokenheartlean
                    *set romance_cg 2
                    Mirella's lips are slightly parted. She seems to hold her breath, guarding the moment from the slightest touch.

                    "Screw it," she says at last, reaching out to cup your cheeks—

                    You jerk back violently, eyes screwing tight. That night loops through your head like a broken @{(romance_wil > 2) record, burning even the thoughts of Wil from your mind.|record.}

                    She's one of them, she's one of them, she's one of them.

                    "Shit. $!{cgmc}?"  
                    *choice
                        #I can't speak.
                            *set disloyal false
                            Throat squeezed shut, you flinch from her.

                            *goto tangledmass
                        #"Sorry, I can't—"
                            *set disloyal false
                            You choke on your words. They were utterly inadequate from the start.

                            *goto tangledmass
                        #"Get away from me."
                            *set disloyal true
                            "Oh." The word falls quiet as a raindrop into the ocean.

                            *label tangledmass
                            @{disloyal There's no fight in your rejection, nor strength. It's the flimsiest shield you can put between you and her.|Retreat's no option in such a tiny room, and closed eyes are no protection from memories.}

                            A tangled mass of razor-tipped thorns snarls your chest, crushing the life from you, bleeding you dry. @{brokenheart Beth is alive, there's so much unresolved, and you're verging on kissing on Mirella? |Prii's blood is on Mirella's hands, and you're on the verge of kissing her?|Shauna would still be a part of your life if it wasn't for Mirella and the Coven. Her cheer, her gentle support, her adorable shyness—and you're verging on kissing Mirella?|Grant would still be a part of your life if it wasn't for Mirella and the Coven. His wit and lazy charm, how adorably vulnerable he was to tease—and you're verging on kissing Mirella?|DUMMY} Faithless, disloyal traitor.

                            @{disloyal You want to scream at her. You want to rip both you and her to pieces and mingle the tattered scraps together.|It almost seems to burn where she touched you.}

                            *choice
                                #Despite everything, my feelings for Mirella are real.
                                    This wouldn't be tearing you up if they weren't. The past and the present each have their hooks in you, gouging in separate directions.

                                    *label shudderingbreatheyes
                                    @{interest_cg With a shuddering breath, you open your eyes.|You force your eyes to open.}

                                    Mirella has backed all the way into the corner, taking as much distance as the limited space allows, looking at once on guard and desperately, painfully fragile.

                                    *if (interest_cg)
                                        @{disloyal "Sorry," you mumble. "That was autopilot. Not your fault." After that display, she probably thinks you hate her.|"That wasn't your fault," you mumble. "It's just… hard."}

                                        She nods fractionally, not relaxing an inch.

                                        "Maybe let's give this a shot another time. If, you know, if you want to." You've trailed off into a whisper by the end of the sentence.

                                        Mirella regards you for a brutally long moment, then sags. Another nod, fuller than the last. "I'd like that," she murmurs.

                                        She was bracing for rejection. @{disloyal You already had, in a way.|How else could she read your response?}

                                        Gradually, the tension dissipates. Mirella extricates herself from her corner. The cage of brambles around your heart eases, and perhaps that's the best outcome you can hope for. If the pain vanished entirely, then @{brokenheart Beth|Prii|Shauna|Grant|DUMMY} would have stopped meaning anything to you.

                                        Gremlink announces that the lockdown is lifted across the PA. You glance at Mirella, then settle your back a little more against the wall. A smile flits across her face.

                                        *label snoozydime
                                        At some stage, your eyes drift closed.

                                        *page_break
                                        "$!{cgmc}."

                                        Wakefulness returns, bringing with it the mother of all cricks in your neck. 

                                        Groaning and grimacing, you raise yourself up from the unforgiving floor. Mirella comes into view, crouching a couple of feet away.

                                        "What… what time is…" you manage, mouth tasting of sand.

                                        "About five in the morning." Mirella shoots you a wry smile, looking about as bad as you feel. "We both passed out, I guess."

                                        "Wugh," you opine. 

                                        Mirella hands you something it takes a bleary-eyed moment to identify is your phone. "It went off a little bit ago," she explains. Sure enough, checking it yields a text from Dion.

                                        [i]We have a lead. Let's discuss tomorrow.[/i]

                                        Pressing a knuckle to either temple in a vain effort to pacify your thumping head, you force out a single word. "Architect."

                                        "Figured. You need to head out?"

                                        You nod gingerly, maybe even regretfully.

                                        "That's too bad." @{touchingokay She reaches out a hand, tentatively taking your own.|She laces her fingers together.} "Talk soon, okay?"

                                        "Yeah, definitely," you @{touchingokay affirm, giving her hand a quick squeeze.|affirm.} You'll have to sort out what this means, what it doesn't, see where you stand with each other. But later.

                                        She smiles with real warmth, the light reaching her eyes.

                                        *if (scrapcat)
                                            As you busy yourself to leave, massaging the back of your neck, her face falls again. "By the way, Catalyst was lurking around yesterday after the meeting. Looking for you, I think. Keep your eyes peeled."

                                            He's always ready to put a shadow over you, huh? You nod. "Thanks for the warning."

                                        *else
                                            You busy yourself to leave, massaging the back of your neck. It doesn't take long to assemble your meagre inventory.


                                        "Stay safe, $!{cgmc}. Try not to get jumped in any more cafés," says Mirella, opening the door for you.

                                        @{(expressive > 60) "Backatcha," you reply.|"Hey, that wasn't my fault," you protest good-naturedly.}

                                        You head out of the annex, out of the dojo, and out of the Coven. You feel as if you could sleep for a week, but with an unanswered text burning a hole in your pocket, it's a pipe dream.

                                        No rest for the villainous.
                                        *goto endofcurrent


                                    *else
                                        @{disloyal "This was a bad idea,"|"I don't think this was a good idea,"} you rasp.

                                        Her lack of reaction is itself a reaction. She was braced for the rejection she'd already seen coming.

                                        But bracing doesn't keep the tremble from her response.

                                        "Probably."

                                        You watch each other, shrouded in lost possibilities. Gremlink announcing the lockdown is lifted across the PA is a welcome mercy-killing.

                                        Without another word exchanged, you get up and exit, leaving Mirella behind.

                                        *page_break
                                        *goto shambleshambleleave

                                #She'll always be Coven. I can't look past that, now or ever. [Block flirting/romance]
                                    *set interest_cg false
                                    *set flirt_cg 0
                                    *set polyflag_acg false
                                    *set romance_cg 1
                                    Whatever feelings you have, they're permanently poisoned by association. You could be a decade clear of the Coven and you still wouldn't forget how you met.

                                    *goto shudderingbreatheyes



            *else
                #@{t_cg Eh. It's more fun that way. Lean in.|Lean in closer.} [Start @{(aro = 1) Romance|Aromantic Relationship}]
                    *label mirellakiss
                    *set flirt_cg +2
                    *set romance_cg 3
                    *achieve ceemance
                    You've been close to Mirella before.

                    Not like this.

                    Her breaths are shallow, like she's afraid that even a misplaced exhalation will shatter the moment. She searches your face, just as you search hers.

                    *if (touchingokay)
                        "Screw it," she says at last, and pulls you into a kiss.

                        *label smoochmiri
                        At first she's tentative, then grows in fervour moment by moment. Her palms cup your cheeks as your mouths meet. 

                        Rough hands, gentle touch. Chapped lips. Yours are probably worse.

                        You break for air.

                        Truth be told, there's a certain novelty in contact with Mirella that doesn't immediately precede being hurled to the ground.

                        Uh—not in that way, though given the hungry look in her eyes, you're convinced she's thinking about it.

                        "Kind of forgot what that feels like," she murmurs huskily.
                        *choice
                            #"Me too."
                                She smiles crookedly. "Guess we're both kind of depressing."

                                "Or depressed," you suggest.

                                "Both," she concludes.

                            #"I didn't."
                                "Well look at you, player," she says, amused.

                            #I say nothing, inhabiting the moment.   
                                After a moment, she smiles, seeming to understand what you're doing.

                            *selectable_if ((dating = false) and (hookup_wyrd = 1)) #"That was my first, actually."
                                "No way."

                                You shrug, @{(romance_wil = 4) though it's accompanied by a brief pang of guilt. Wil asked to wait.|just a little bashfully.}

                                Mirella lets out a [i]very[/i] girly giggle, taking you completely by surprise. "That's cute as hell."

                        You take one another in for a moment, and then you're kissing again. Slower. A notch more intense. Mirella kisses like she's trying to imprint it into her mind, and you let her, focusing on the feeling of her lips on yours, the warmth of her body, not quite touching your own.

                        There's wetness on your face. Mirella pulls back again, rubbing at her eyes. "Ugh. Embarrassing," she half-mutters, half-growls. "Sorry, $!{cgmc}. It's not you."
                        *choice
                            #Ask if she's okay.
                                "Yeah. No. I don't know." She lowers her arm and smiles through the tears. It doesn't look forced. "A lot of things hitting all at once."

                                *label understanding
                                You nod your understanding. A whole lot of emotion is running through your chest right this moment, squeezing it tight one second, filling it with warmth the next.

                                Mirella doesn't go for another kiss, and neither do you. Instead, you reclaim your positions seated on the floor, @{touchingokay shoulder meeting shoulder,|shoulders almost meeting,} sharing one another's presence and stealing occasional furtive smiles.

                                *goto snoozydime
                            #Give her a moment.
                                She scrubs her eyes a little longer, then lowers her arm, taking a couple of deep breaths. She smiles through the tears, and it doesn't look forced. "Thanks. Just a lot of things hitting at once, you know?"

                                *goto understanding

                    *else
                        "Screw it," she says at last. "Can I kiss you?"
                        *choice
                            #Yes. Yes she can.
                                Your nod is as tentative as her breathing. 

                                She reaches out and pulls you to her.

                                *goto smoochmiri
                            #Clarify how I feel about touching.
                                "I'm not really—physical stuff isn't always comfortable for me. Thanks for asking."

                                "Oh. Alright." She chews her lower lip. "Sorry, I thought you were—I got the wrong idea."

                                "The right idea," you counter. "Not wanting to kiss doesn't mean I don't want you."

                                …

                                Those sure were some words that just came out of your mouth. Cheeks warming, you look away.

                                "Well, when you put it like that…" murmurs Mirella.

                                In lieu of any kissing, you settle back in at each other's sides, seated on the floor with shoulders almost meeting. You're content sharing one another's presence, stealing occasional furtive smiles.

                                *goto snoozydime

            #I have zero energy to think clearly on this.
                *set hesitate_cg 2
                *label i_anyway
                "I… anyway," you mumble. It's not even a sentence, but it suffices to break the moment's hold on you both.

                *label awkwardminutes
                A few @{interest_cg awkward minutes pass by as the weight of what's going unspoken hangs overhead,|minutes pass by in a companionably content-slash-exhausted silence,} and then Gremlink pipes up through the PA, letting everyone know that the lockdown is lifted.

                *goto guessgetgoing

            #I don't want anything with her. [Block flirting/romance]
                *set interest_cg false
                *set flirt_cg 0
                *set polyflag_acg false
                *set romance_cg 1
                "Let's… leave this the way it is, alright?" you say.

                Mirella blinks as if snapping free from a spell and leans backward. She gives a short, sharp nod. "I hear you," she replies, smiling again with no apparent hard feelings.

                You nod back, feeling just a little tension easing from your shoulders. These emotions are complicated, so… that definitely could have gone worse.

                *goto awkwardminutes
    
*else
    [i]"Sup peeps?"[/i] Gremlink pipes up through the PA, snapping the moment like a twig. [i]"We're back to standard security and the doors are unlocked. Don't forget to shut them behind you! Later!"[/i]
    
    *label guessgetgoing
    "Guess we should get going," $!{cg}—Mirella—murmurs, just a little regretfully. "You head out first; protocol says not to leave in groups." @{scrapcat She grimaces. "I know this probably goes without saying, but watch out for Catalyst. He was lurking earlier, and I think it was you he was after, $!{cgmc}."|}
    
    @{scrapcat Fuck. "I appreciate the warning. See you later."|You nod. Sounds reasonable.}
    
    *page_break Time to leave.
    *goto shambleshambleleave


*label endofcurrent
*achieve nextphase
*finish

